In macOS Sierra , se hai solo un normale mouse USB , non uno fornito con il proprio software ed è multifunzione con pulsanti aggiuntivi, ecc., quindi in Preferenze di sistema > Mouse , hai le seguenti impostazioni che possono essere modificate:
-
Direzione di scorrimento: naturale casella di controllo
-
Velocità di tracciamento dispositivo di scorrimento
-
Velocità di scorrimento dispositivo di scorrimento
-
Velocità del doppio clic slider
E due ulteriori impostazioni in Mouse che non verranno indirizzate, per due motivi, il pulsante del mouse principale: pulsanti di opzione , se altro quindi predefinito di Sinistra , è probabilmente già impostato e non cambierebbe necessariamente perché si desidera modificare la direzione di scorrimento: naturale < em> checkbox e dato che l'OP ha indicato mouse USB , presumo che non stia utilizzando Bluetooth e che possa ignorare il mouse Bluetooth di installazione. . pulsante .
Questa risposta utilizzerà AppleScript per ottenere le prima e dopo per il valore del i slider elencati in precedenza devono essere utilizzati nel codice AppleScript che segue dopo questo codice .
Apri Script Editor e crea un nuovo documento, quindi aggiungi il seguente codice :
tell application "System Preferences"
set current pane to pane id "com.apple.preference.mouse"
--delay 0.5 -- # If necessary, uncomment 'delay' command and set its value in seconds and or decimal fractions there of.
tell application "System Events"
log "Scrolling speed is set to: " & value in (get properties of slider 1 of front window of application process "System Preferences")
log "Double-Click speed is set to: " & value in (get properties of slider 2 of front window of application process "System Preferences")
log "Tracking speed is set to: " & value in (get properties of slider 3 of front window of application process "System Preferences")
end tell
end tell
Ci saranno due stati della direzione di scorrimento: naturale casella di controllo in Preferenze di sistema > Mouse , controllato e deselezionato e la modifica delle impostazioni slider tra i due stati .
Il codice sopra verrà eseguito una volta per ottenere le impostazioni value correnti degli slider . Quindi apporta le modifiche alle impostazioni desiderate agli cursori per lo stato opposto di ciò che erano quando hai raccolto i valori delle prime impostazioni per il primo stato . Quindi esegui nuovamente il codice per ottenere le impostazioni della differenza.
Quindi inserirai i valori , raccolti sopra, nel codice sotto. Puoi commentare o rimuovere qualsiasi dispositivo di scorrimento che non verrà modificato dal codice di seguito.
I commenti nel codice sotto dovrebbero essere adeguati, tuttavia, non esitare a chiedere che hai bisogno di spiegazioni.
Ho salvato il seguente codice AppleScript in Script Editor come applicazione denominata Attiva / disattiva impostazioni mouse nel < strong> cartella Applicazioni .
Quando è in esecuzione, attiva lo stato della direzione di scorrimento: naturale checkbox tra controllato e deselezionato insieme alle impostazioni slider sotto ogni stato .
AppleScript codice per l'applicazione Attiva / disattiva impostazioni mouse :
on run
try
tell application "System Preferences"
set current pane to pane id "com.apple.preference.mouse"
-- delay 0.5 -- # If necessary, uncomment 'delay' command and set its value in seconds and or decimal fractions there of.
tell application "System Events"
set isChecked to get value of checkbox 1 of front window of application process "System Preferences" as boolean
if isChecked then
-- # The 'Scroll direction: Natural' checkbox is checked, uncheck it.
set cbValue to value of (click checkbox 1 of front window of application process "System Preferences") as boolean
-- # Scrolling Speed - Valid Values: 0.0 to 8.0
set value of slider 1 of front window of application process "System Preferences" to 6.0
-- # Double-Click Speed - Valid Values: 0.0 to 10.0
set value of slider 2 of front window of application process "System Preferences" to 8.0
-- # Tracking Speed - Valid Values: 0.0 to 9.0
set value of slider 3 of front window of application process "System Preferences" to 6.0
else
-- # The 'Scroll direction: Natural' checkbox is not checked, check it.
set cbValue to value of (click checkbox 1 of front window of application process "System Preferences") as boolean
-- # Scrolling Speed - Valid Values: 0.0 to 8.0
set value of slider 1 of front window of application process "System Preferences" to 4.5
-- # Double-Click Speed - Valid Values: 0.0 to 10.0
set value of slider 2 of front window of application process "System Preferences" to 8.0
-- # Tracking Speed - Valid Values: 0.0 to 9.0
set value of slider 3 of front window of application process "System Preferences" to 4.0
end if
end tell
tell me
if cbValue then
display notification "Natural scrolling is now active." with title (name of me)
else
display notification "Natural scrolling is no longer active." with title (name of me)
end if
end tell
quit
end tell
on error eStr number eNum
activate
display dialog eStr & " number " & eNum buttons {"OK"} default button 1 with title "Toggle Mouse Settings" with icon caution
tell application "System Preferences" to quit
return
end try
end run
Nota: prima di eseguire l'app Attiva / disattiva impostazioni mouse , devi aggiungerla a: Preferenze di sistema > Sicurezza e amp; Privacy > Privacy > Accessibilità
C'è un'app chiamata EventScripts che può essere utilizzata per attivare quando un dispositivo USB è collegato o rimosso. Non l'ho usato prima, solo consapevole che esiste.
C'è anche un'app chiamata Scroll Reverser . Non l'ho usato prima, solo consapevole che esiste.