Crea un servizio con Automator - Testato su macOS Sierra

1. Apri /Applications/Automator.app
2. File > Nuovo (cmd-N)
   • Scegli un tipo di documento: "Servizio".
3. Il servizio riceve selezionato: "file o cartelle" in "Finder".
4. Nel riquadro di sinistra vai a: Azioni > Libreria > Utilità > Esegui AppleScript.
   • Trascina l'elemento "Esegui AppleScript" dal riquadro della libreria a sinistra nel riquadro del codice sorgente sulla destra.
5. Cancella completamente il contenuto precompilato. Incolla il seguente codice sorgente:

Codice sorgente AppleScript

use framework "Foundation" -- Cocoa-AppleScript

on run {input, parameters}
    repeat with thisItem in input
        tell application "Finder"
            if kind of thisItem is "Alias" then -- alias file only
                set parentPath to container of thisItem -- get the folder of this alias
                set {label index:l, comment:c, modification date:m, creation date:cr, original item:origPath, name:n} to properties of (item thisItem)
                if origPath is not missing value then -- not a breaking alias
                    set tagsList to (my tagsFor:(POSIX path of thisItem)) -- get the tags of the alias file (call an AppleScriptObjC handler)
                    delete thisItem -- move this alias to the trash

                    -- ** create an alias file **
                    set newAliasFile to make new alias at parentPath to origPath with properties {comment:c, creation date:cr, original item:origPath, name:n}
                    -- ** set the label ** (0 = no label)
                    if l is not 0 then set label index of newAliasFile to l
                    -- ** set  the tags ** ({} = no tag) 
                    if tagsList is not {} then (my setTags:tagsList forPath:(POSIX path of (newAliasFile as string))) -- call an AppleScriptObjC handler
                    -- ** change the modification date **
                    set modification date of newAliasFile to m
                end if
            end if
        end tell
    end repeat
end run

on tagsFor:posixPath -- Cocoa-AppleScript handler 
    set fileURL to current application's |NSURL|'s fileURLWithPath:posixPath
    set {theResult, theTags} to fileURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags = missing value then return {} -- no tags
    return theTags as list
end tagsFor:

on setTags:tagList forPath:posixPath -- Cocoa-AppleScript handler
    set fileURL to current application's |NSURL|'s fileURLWithPath:posixPath
    fileURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end setTags:forPath:

6. File > Salva (cmd-S): Assegna un nome come "Alias ricreazione".
7. Apri le Preferenze di Sistema > Tastiera > Tasti di scelta rapida > Servizi > File e cartelle > Alias ricreazione, o comunque lo hai nominato.
   • Assegna una scorciatoia. Come cmd-L si usa per creare un alias (L come in "link"), l'ho assegnato a cmd-alt-ctrl-L.
8. Seleziona uno o più file alias legacy ed elaborali.
   • Con il tuo collegamento cmd-alt-ctrl-L.
   • o tramite il menu principale: Finder > Servizi > File e cartelle > Alias ricreazione.

Nota : il processo batch è molto trasparente e gli errori possono essere corretti. Gli alias cancellati vengono spostati nel cestino. Se hai commesso un errore, scegli il file alias trash in questione ed esegui Finder > Metti indietro (cmd-backspace). Ciò riporterà il file nella sua cartella padre precedente e aprirà la cartella genitore in una nuova finestra. Poi hai l'alias ricreato e l'alias originale con il suffisso "copia" affiancato e puoi apportare correzioni se necessario.