Come si può saltare a una linea specifica in Numbers?

Se hai problemi ad aprire il file e vuoi solo vedere quella linea prova quanto segue in Terminale. Se non hai mai utilizzato Terminal in precedenza, tieni presente che devi passare alla directory in cui il file è il primo, il più semplice è copiare quel file sul desktop ed eseguire il seguente comando in Terminal per navigare nella cartella del desktop:

cd ~/Desktop

Quindi esegui questo comando:

head -4223860 mybigfile.csv|tail -1 > export.csv

dove "mybigfile.csv" sarebbe il tuo nome file e export.csv è il nome del file esportato. Puoi anche visualizzare la linea in un terminale senza salvare alcun file con:

head -4223860 mybigfile.csv|tail -1

Non puoi farlo in Numbers in modo nativo, ma AppleScript aiuta:

1. Crea un select_cell AppleScript in Script Editor con il seguente contenuto:

   _main()
   on _main()
       tell application "Numbers"
           if not (exists document 1) then return
           set {table:_table} to my _selection(document 1)
           if _table is missing value then
               display dialog "Select some cell(s) in target table first"
               return
           end if
           tell _table
               set {rk, cn} to {count rows, column -1's name}
           end tell
   
           repeat
               display dialog "Enter cell name" & return & ¬
                   "  row in 1.." & rk & return & ¬
                   "  column A.." & cn default answer ("A" & rk) with title "Select Cell"
               set cellname to text returned of result
               try
                   tell _table
                       set selection range to range cellname
                   end tell
                   exit repeat
               on error
                   display dialog "Unable to select the specified cell: " & cellname
               end try
           end repeat
       end tell
   end _main
   
   on _selection(doc)
       (*  
           reference doc : target document  
           return record : {range:_range, table:_table, sheet:_sheet}  
               _range = reference to named range in selection  
               _table = table object to which selection range belongs  
               _sheet = sheet object to which selection range belongs  
       *)
       (*  
           Limitation  
               Numbers allows to select uncontinuous regions  
               but its scripting interface does not provide decent method to retrieve them.  
   
               If uncontinuous regions are selected, 'selection range' returns the minimum continuous region  
               which includes all the regions in selection.  
       *)
       script o
           property parent : {}
           property pp : {}
           local q, r, s, _range, _table, _sheet
           tell application "Numbers"
               set pp to doc's every sheet's every table's selection range as list
               repeat with p in my pp -- per sheet  
                   set q to p's every specifier -- retrieve object (filtering out missing value)  
                   if q ≠ {} then
                       set q to q's item 1 -- selection range object [1]  
                       set r to q as record -- selection range object specifier record [2]  
                       set _table to r's every specifier's item 1 -- container table reference [3]  
                       set s to (a reference to _table's selection range) -- selection range reference [4]  
                       set _range to (a reference to _table's range (s's name)) -- named range reference [5]  
                       set _sheet to (_table as record)'s every specifier's item 1 -- container sheet reference [3]  
                       return {range:_range, table:_table, sheet:_sheet}
                   end if
               end repeat
               return {range:missing value, table:missing value, sheet:missing value}
           end tell
           (*  
               [1] class specifier for 'range' is broken in Numbers 09  
               [2] «class want» value is broken in Numbers 09  
               [3] simple method to get «class from» value without asking for «class from» key which causes trouble in recompilation of the token 'from'.  
               [4] proper reference of selection range object  
               [5] proper reference of named range object  
           *)
       end script
       tell o to run
   end _selection
   

   e posizionalo in ~ / Libreria / Script / Applicazioni / Numeri.

2. Nelle preferenze di Script Editor scegliere "Generale" e abilitare "Mostra menu Script nella barra dei menu".
3. Ora, se vuoi passare a una cella in un documento Numbers aperto, apri il menu di script nella barra dei menu - > select_cell e immettere le coordinate della cella (ad esempio B56 o A12094). La cella deve esistere però: se il tuo file Numbers contiene solo 120 righe e 2 colonne non puoi saltare alla cella G1500.

Un limite di 65535 righe e 255 colonne sembra esistere per i file di Numbers. Quindi una "linea" 4223860 non può essere importata e di conseguenza non può essere mostrata.

Testato in 10.9.5 e Numbers 3.2.2. Rubato senza vergogna lì: fonte - che fornisce anche altri metodi, incluso uno con una scorciatoia.