Elimina un file attualmente aperto direttamente nell'applicazione?

Io uso questo AppleScript:

tell application (path to frontmost application as text)
    set f to POSIX file (path of document 1) as text
    close document 1
end tell
tell application "Finder" to move f to trash

Una versione hackier che funziona con alcune altre applicazioni:

try
    tell document 1 of application (path to frontmost application as text)
        set f to path
        close
    end tell
on error
    tell application "System Events" to tell (process 1 whose frontmost is true)
        value of attribute "AXDocument" of window 1
        set f to do shell script "x=" & quoted form of result & ";x=${x/#file:\/\/};x=${x/#localhost/};printf ${x//%/\\x}"
        keystroke "w" using command down
    end tell
end try
POSIX file f
tell application "Finder" to move result to trash

Prova questo AppleScript in un servizio di Automator (puoi assegnare un tasto di scelta rapida a qualsiasi servizio):

on run
    set x to path to frontmost application as string
    tell application x to if exists document 1 then
        try
            try
                set p to path of front document -- some app use --> path of document
                p
            on error
                set p to file of front document -- some app use -->  file of document
            end try
            my moveToTrash(p)
            close front document
        on error
            my speakText("can't delete this document")
        end try
    else
        my speakText("You have no open document in that application")
    end if
end run

on moveToTrash(p)
    if p starts with "/" then -- some app return posix path
        set tFile to p as POSIX file as alias
    else -- some app return HFS path
        set tFile to p as alias
    end if
    tell application "Finder" to delete tFile
end moveToTrash

on speakText(t)
    say t
end speakText

Ho testato lo script su queste applicazioni ( "BBEdit", "TextWrangler", "TextEdit", "Anteprima" "QuickTime Player", "Pages", "Numbers", "Keynote", "Automator", "AppleScript Editor", "Xcode" ) su Mavericks

Questo script non funzionerà con alcune applicazioni non Apple.

Per assegnare una combinazione di tasti al servizio appena creato:

Apri l'applicazione Preferenze di sistema e vai al pannello delle preferenze della tastiera e seleziona la scheda Scorciatoie. Dall'elenco a sinistra del pannello delle preferenze, selezionare la categoria Servizi. Un elenco dei servizi installati verrà visualizzato a destra. Scorri fino all'ultima categoria intitolata Generale e individua il servizio appena creato. Fare doppio clic all'estrema destra del nome del servizio per attivare il campo di immissione della sequenza di tasti e quindi digitare la combinazione di tasti che si desidera assegnare al servizio. Chiudi l'applicazione Preferenze di sistema.