Sono interessato a creare un servizio (utilizzando Automator se possibile) che mi consente di eseguire un'azione su un URL.
Se l'URL esiste come testo normale, funziona perfettamente.
Tuttavia, se l'URL è un link in formato RTF, il mio servizio ottiene il titolo del link, piuttosto che il suo URL.
Come posso ottenere l'URL quando si attiva un servizio su un collegamento RTF?
Puoi farlo utilizzando l'app TextSoap . I pulitori "Estrai URL sostituendo" e "Estrai URL aggiungendo" funzionano in formato RTF.
Puoi anche utilizzare il seguente AppleScript:
tell application "textsoap7"
cleanClipboard with "Extract URLs by Replacing"
end tell
Ho avuto lo stesso identico problema quando volevo essere in grado di avviare determinati collegamenti nel mio browser non predefinito e soluzioni come LinCastor non funzionavano per me. Ecco cosa ho fatto (dopo un TON di Google e ore di corsa contro muri di mattoni):
Crea servizio
Ho creato un Service in Automator che riceve rich text in any application . Poi ho creato una serie di azioni (tutte di Run AppleScript ) per trasformare i dati selezionati, a poco a poco, nell'URL desiderato. Le seguenti sezioni illustrano i passaggi.
Per essere precisi, questi sono tutti passaggi all'interno di un singolo flusso di lavoro, e tutti sono nell'ordine elencato qui (ogni fase consuma il risultato del passaggio precedente).
Modifica : per chi non ha familiarità con l'utilizzo di questo servizio, è possibile fare clic su qualsiasi collegamento in qualsiasi applicazione (stavo usando collegamenti in posta che erano rich text, il che significa che il testo visualizzato non era l'URL) e cercare il sottomenu Servizi nel popup. Scegli il tuo servizio da quella lista, et voilà!
Ottieni i dati
on run {input}
-- Save off the old clipboard data and capture the current selection in its entirety
set oldClipboard to the clipboard as record
tell application "System Events" to keystroke "c" using command down
set plistData to ""
set retries to 50
-- Try to get the pList data from the clipboard (may take a little while to appear)
repeat while plistData = ""
set clipboardRecord to the clipboard as record
try
set plistData to «class weba» of clipboardRecord
-- In case you want to use RTF instead...
--set clipRTF to «class RTF » of clipboardRecord
on error msg
set retries to retries - 1
-- If we're out of retries then bail
if retries < 0 then
set the clipboard to oldClipboard
display dialog ("Failed to get the web data: " & msg) buttons {"OK"} default button 1
error number -1
end if
-- ...else ignore the error and retry after a small delay
delay 0.1
end try
end repeat
-- Restore the old clipboard data
set the clipboard to oldClipboard
-- Set up our intermediate plist file
set plistFileName to (path to temporary items as text) & "safarilink.plist"
set plistFRef to (open for access file plistFileName with write permission)
try
set eof plistFRef to 0
write plistData to plistFRef
close access plistFRef
--display dialog plistFileName
on error msg
display dialog ("PList write error: " & msg) buttons {"OK"} default button 1
close access plistFRef
error number -1
end try
-- Pass the pList file name to the next step
return plistFileName
end run
Estrai il link HTML
on run {input, parameters}
set plistFileName to (input as text)
-- Set up our intermediate HTML link file
set linkHtmlFileName to (path to temporary items as text) & "safarilink.html"
set linkHtmlFRef to (open for access file linkHtmlFileName with write permission)
try
tell application "System Events"
set plist to property list file plistFileName
set entry to contents of plist
--display dialog "Name: " & (name of entry)
--display dialog "Kind: " & (kind of entry)
--display dialog "Text: " & (text of entry)
set valueRec to (value of entry as record)
set webMainResource to webMainResource of valueRec
set webResourceData to webResourceData of webMainResource
--display dialog "Resourced"
set eof linkHtmlFRef to 0
write webResourceData to linkHtmlFRef
close access linkHtmlFRef
end tell
on error msg
display dialog ("Link HTML generation error: " & msg) buttons {"OK"} default button 1
close access linkHtmlFRef
error number -1
end try
-- Pass the HTML link file name to the next step
return linkHtmlFileName
end run
Carica il codice HTML ed Estrai l'URL
on run {input, parameters}
set linkHtmlFileName to (input as text)
--set fileSize to 0
--tell application "Finder" to set fileSize to size of file linkHtmlFileName
try
set htmlContentParts to read file linkHtmlFileName using delimiter "="
on error msg
display dialog ("Link HTML load error: " & msg) buttons {"OK"} default button 1
close access htmlFRef
error number -1
end try
set hrefIndex to -1
repeat with index from 1 to count of htmlContentParts
if item index of htmlContentParts ends with "href" then
set hrefIndex to index
end if
end repeat
if hrefIndex = -1 then
display dialog "Selection does not contain a link!" buttons {"OK"} default button 1
error number -1
end if
set linkPart to item (hrefIndex + 1) of htmlContentParts
set splitParts to split(linkPart, "\"")
return item 2 of splitParts --index is base-1
end run
on split(theString, theDelimiter)
-- Save delimiters to restore old settings
set oldDelimiters to AppleScript's text item delimiters
-- Set delimiters to delimiter to be used
set AppleScript's text item delimiters to theDelimiter
-- Create the array
set theArray to every text item of theString
-- Restore the old setting
set AppleScript's text item delimiters to oldDelimiters
-- Return the result
return theArray
end split
A questo punto, hai il tuo URL (assicurati di convertirlo esplicitamente in testo, per non finire con misteriosi errori AppleScript.) Da qui, l'ho usato per caricare automaticamente il link in Safari.
Usa il tuo URL
on run {input, parameters}
set linkURL to (input as text)
try
tell application "Safari"
if not (exists first window) then
make new window
set URL of last tab of first window to linkURL
set visible of first window to true
else
tell first window
set newTab to make new tab with properties {URL:linkURL}
set visible to true
set current tab to newTab
end tell
end if
activate
end tell
on error msg
display dialog ("Failed to load URL (" & linkURL & ") in Safari: " & msg) buttons {"OK"} default button 1
error number -1
end try
end run
Divertiti e spero che questo aiuti!