Ecco un metodo AppleScript, che dimostra tre diversi tipi di azioni sulle righe con voci di cella duplicate in columns "A" e "B" (equivalente a cells 1 e 2 ):
use N : application "Numbers"
--------------------------------------------------------------------------------
# PROPERTY VALUES & GLOBAL VARIABLES
property document : a reference to document 1 of N
property sheet : a reference to active sheet of my document
property table : a reference to table 1 of my sheet
global them
--------------------------------------------------------------------------------
# IMPLEMENTATION:
on run
if not (exists my table) then return false
set them to a reference to (every row of my table ¬
where the value of cell 1 = the value of cell 2 ¬
and the value of cell 1 ≠ missing value)
highlight()
---OR:
-- comment()
--OR:
-- delete -- WARNING: permanent!
end run
--------------------------------------------------------------------------------
# HANDLERS:
to highlight()
set the background color of them to ¬
{65535, 65535 / 4, 65535 / 2}
end highlight
to delete
delete them
end delete
to comment()
set the value of cell 3 of them to "SNAP!"
end comment
---------------------------------------------------------------------------❮END❯
Ho definito tre gestori, highlight() , comment() e delete , ognuno dei quali, se chiamato, eseguirà una particolare azione sulle righe di interesse. Attualmente, puoi vedere nello script alcune righe all'interno della sezione IMPLEMENTATION: che ho impostato attualmente per eseguire l'azione highlight() , che cambierà il colore di sfondo delle righe particolari con una sfumatura di rosa che mi piace.
Sotto questa riga ci sono i comandi che ho commentato usando -- , quindi al momento restano inerti. Quando non commentato, il gestore comment() inserirà la parola "SNAP!" nella terza colonna di ogni riga di interesse; e il comando delete (notare la mancanza di parentesi per questo) eliminerà semplicemente completamente le righe. L'ho contrassegnato con un avviso che implica l'eliminazione permanente, anche se in verità è possibile richiamare le righe esistenti utilizzando la voce di menu Annulla incorporata dell'applicazione o ⌘ < kbd> Z (su base uno per uno!)
