Utilizzo del metodo integrato

Come per Knowledge Base di Apple , Numbers supporta riferimenti assoluti :

You can set row and column references in a formula to be absolute so that you can use the same formula elsewhere in your spreadsheet without the cell references changing, as they would otherwise.

Per modificare la formula originale per utilizzare riferimenti assoluti, procedi nel seguente modo:

1. Fai doppio clic sulla cella originale per passare alla modalità di modifica.
2. Per ogni riferimento, clicca sul triangolo; quindi seleziona entrambe le caselle Mantieni riga e Mantieni colonna

Oppure, in alternativa al passaggio 2, puoi modificare manualmente il riferimento per dire e. g. $A$1 anziché A1 .

Gli ovvi inconvenienti di questo metodo sono:

• Il metodo blocca fondamentalmente la tua formula in una modalità che rende difficile riutilizzare la stessa formula in altre parti in cui vuoi riferimenti flessibili

• Se vuoi copiare molte diverse formule originali, devi ripetere il metodo più e più volte.

Uso di un AppleScript per Copia formule

Un approccio più riutilizzabile sarebbe un semplice AppleScript che replica il comando Copia ma copia solo le formule nulle:

on join(cells, delimiter)
  set previousDelimiters to AppleScript's text item delimiters
  set AppleScript's text item delimiters to delimiter
  set resultString to (cells as text)
  set AppleScript's text item delimiters to previousDelimiters
  return resultString
end join

on getSelectedFormulas()
  set tab to character id 9
  set lf to character id 10

  tell application "Numbers"
    tell document 1's sheet 1's table 1
      tell selection range
        set {min, max} to {column 1's address, column -1's address}
        set formulaRows to {}
        repeat with aRow in rows
          set formulaCells to {}
          repeat with aCell in aRow's cells min thru max
            set formulaCells to formulaCells & (aCell's formula)
          end repeat
          set formulaRows to formulaRows & ¬
            my join(formulaCells, tab)
        end repeat
        return my join(formulaRows, lf)
      end tell
    end tell
  end tell
end getSelectedFormulas

on run()
  tell application "Numbers"
    set the clipboard to my getSelectedFormulas()
  end tell
end run

(Nota: sono l'autore della sceneggiatura, è sotto la licenza open source ISC .)

Questo elimina anche la necessità di modificare le formule originali.

Associazione dello script a una scelta rapida da tastiera

Per collegare questo script a una scorciatoia da tastiera in Numbers, apri Automator.app per creare un flusso di lavoro di Automator. Scegli l'opzione Il servizio non riceve input in Numbers , crea un singolo passaggio Esegui AppleScript e incolla il codice AppleScript lì.

Salva il flusso di lavoro sotto il nome Copy Formulas , quindi apri Preferenze di sistema e fai clic su Tastiera, quindi Tasti di scelta rapida » Servizi » Numeri » Copia formule. Configura una scorciatoia da tastiera; Consiglierei ⌥⇧⌘C perché probabilmente lo userai spesso con la sua controparte, Incolla e abbina stile, che ha già la scorciatoia ⌥ ⇧⌘V .