C'è un modo per fare una presentazione di tutti i video e le immagini contenute in una singola cartella?

Question

C'è un modo per fare una presentazione di tutti i video e le immagini contenute in una singola cartella?

#1 da (4 voti)

2

Sto impostando una presentazione di uno spazio di vendita. Idealmente, voglio avere una cartella di video e immagini che possono essere aggiunti o rimossi e aggiorneremo la presentazione. Simile allo screensaver della presentazione, ma con capacità video. C'è un'app per fare questo o qualcosa di scriptable?

mac slideshow

posta BoetW 29.07.2018 - 20:29

fonte

1 risposta

Leggi altre domande sui tag mac slideshow

Impossibile ridimensionare la partizione su VMWare Mac Posso riprodurre registrazioni di memo vocali utilizzando un'altra app? [duplicare]

score 4 · Answer 1

Apri /Applications/Photos.app e vai a File > Nuovo album.
Crea un nuovo album con il nome "Store Display"
Apri /Applications/Utilities/Script Editor.app
Copia e incolla lo script di seguito
Vai a File > Esporta
- Formato file: Applicazione
Apri l'applicazione
Seleziona la tua cartella che contiene foto e video
Fai clic su Scegli
Celebrate!

Ecco il codice (modificato da @ wch1zpink):

set imageNameExtensions to {"jpg", "jpeg", "png", "tiff", "bmp", "gif"}
set videoNameExtensions to {"mov", "mp4", "m4v", "avi"}
set nameExtensions to (videoNameExtensions & imageNameExtensions)

set myFolder to (choose folder) as text

set theChoice to display dialog ¬
    "Select Your Option" buttons {"Cancel", "Main Folder", "Main Folder And Sub-Folders"} ¬
    default button 3 ¬
    cancel button 1 ¬
    with title ¬
    "CHOOSE A FOLDER" giving up after 30

if button returned of theChoice is "Main Folder And Sub-Folders" then
    tell application "Finder"
        set mediaItems to (files of (entire contents of folder myFolder) ¬
            whose name extension is in nameExtensions) as alias list
    end tell
else if button returned of theChoice is "Main Folder" then
    tell application "Finder"
        set mediaItems to (files of (folder myFolder) ¬
            whose name extension is in nameExtensions) as alias list
    end tell
end if

tell application "Photos"
    import mediaItems into container named "Store Display" with skip check duplicates
    start slideshow using media items of album "Store Display"
end tell