Consente di aprire i file JPEG in anteprima

Naviga le tue risposte
3

Ho già dato un'occhiata ai forum per una risposta al problema, ma la maggior parte delle volte è nel contesto dei file batch converting (con nomi diversi). Voglio solo aprire una gamma di file JPEG in Anteprima.

Catturo immagini di oggetti di particelle nel mio laboratorio usando "Workflow" per iOS. Questo ha uno script a parte che salva i file nel formato 00000-0.JPG dove i primi cinque zeri sono il numero dell'articolo e lo zero finale è l'ordine sequenziale di quell'elemento particolare. ad esempio 78934-4.JPG è la quarta foto dell'articolo "78934". Il numero di immagini per un dato oggetto può variare molto.

Tutti finiscono in una cartella (sul mio Mac) con diverse migliaia di altre immagini, tutte con la stessa convenzione di denominazione. Vorrei accelerare il processo di ricerca e apertura di questi (simile a essere in Finder, selezionare una gamma di immagini a mano e fare doppio clic sulla gamma e averle aperte in una "istanza" o finestra di Anteprima - per ridurre al minimo l'avere trascinare Windows) con AppleScript.

Ecco quello che ho scritto finora ... 

tell application "Finder" to set myFiles to folder "Macintosh SSD:Users:me:ownCloud:Bilder_neu:Einzelbilder"

set file_extention to ".JPG"

set articleNumber to display dialog "Please enter article number" default answer "" with icon note buttons {"Cancel", "Continue"} default button "Continue"

Non sono sicuro di come gestire il "ciclo for" per trovare e quindi aprire le immagini.

Grazie per l'aiuto fornito

    
posta William Lombard 02.02.2018 - 10:30
fonte

2 risposte

1

Il seguente esempio codice AppleScript presuppone che macOS predefinito di immagini l'apertura in Anteprima è ancora in riproduzione. 

set theImages to quoted form of POSIX path of ¬
    ((path to home folder as string) & "ownCloud:Bilder_neu:Einzelbilder")

set articleNumber to text returned of ¬
    (display dialog "Please enter article number:" default answer ¬
        "" with icon note buttons {"Cancel", "Continue"} default button "Continue")

do shell script "find " & theImages & " -type f -iname '" & articleNumber & "-*.JPG' -exec open {} +"

Se Anteprima non è il gestore predefinito per i file immagine, quindi modifica il do shell script comando in: 

do shell script "open -a Preview $(find " & theImages & " -type f -iname '" & articleNumber & "-*.JPG')"

Nota che " pure AppleScript" non è richiesto!

Nota: il esempio codice AppleScript è proprio questo e non impiega alcuna gestione degli errori e si intende solo per mostrare uno dei molti modi in cui eseguire un compito. L'onere è sempre sull'utente di aggiungere / utilizzare la gestione degli errori appropriata come necessario / voluto.

    
risposta data 02.02.2018 - 12:27
fonte
0

Ecco un puro AppleScript per raggiungere il tuo obiettivo: 

set ImagesFolder to "/Users/me/ownCloud/Bilder_neu/Einzelbilder"

set articleNumber to text returned of (display dialog ¬
    "Please enter article number" default answer ¬
    "" with icon note buttons {"Cancel", "Continue"} ¬
    default button "Continue")

tell application "System Events" to set JPGs to ¬
    path of every file in folder ImagesFolder whose ¬
    type identifier is "public.jpeg" and ¬
    name begins with (articleNumber & "-")

tell application "Preview" to open JPGs
    
risposta data 02.02.2018 - 13:40
fonte

Leggi altre domande sui tag

Forza un'app a Nap Dove viene gestito il rendering subpixel?