Applescript: salva tutte le schede aperte in Chrome in PDF

Question

Applescript: salva tutte le schede aperte in Chrome in PDF

#1 da (0 voti)

3

Mi piacerebbe creare un AppleScript che salva tutte le schede aperte nella finestra frontale di Google Chrome in un PDF.

Questo è il mio MWE operativo finora:

tell application "Google Chrome"
    set allTabs to tabs in front window
    repeat with myTab in allTabs
        tell myTab to print
    end repeat
end tell

Naturalmente, questo apre semplicemente la finestra di stampa ripetutamente per ogni scheda aperta.

Idealmente, potrei salvarli tutti in un PDF distinto, qualcosa del genere (usando alcuni comandi inventati qui):

tell application "Google Chrome"
    set myFolder to "/Users/nnn/Desktop/PDF/"
    set myCount to 0
    repeat with myTab in allTabs
        set myCount to myCount + 1
        set fileName to "pdf" & myCount & ".pdf"
        set outputPath to myFolder & fileName
        export myTab to outputPath as PDF  -- obviously, this does not work.
    end repeat
end tell

Come potrei farlo funzionare?

pdf google-chrome applescript

posta AthanasiusOfAlex 09.12.2018 - 15:21

fonte

1 risposta

Leggi altre domande sui tag pdf google-chrome applescript

Posso bloccare il pannello Preferenze di sistema di iCloud? Come diagnosticare le prestazioni lente del trasferimento file?

score 0 · Accepted Answer

Ho trovato un work-around, usando lo scripting dell'interfaccia utente, che fa ciò di cui ho bisogno:

tell application "Google Chrome"
    set myWindow to front window
    set myTabs to tabs in myWindow


    set outputFolder to "/Users/nnn/Desktop/PDF/"
    set myCount to 0

    activate

    repeat with myTab in myTabs
        set myCount to myCount + 1
        set fileName to "pdf" & myCount & ".pdf"
        set outputPath to outputFolder & fileName

        --N.B.: the following opens the system print window, not Google Chrome’s
        tell myTab to print

        tell application "System Events"
            tell process "Google Chrome"
                repeat until window "Print" exists
                    delay 0.02
                end repeat

                set printWindow to window "Print"

                tell printWindow
                    set myButton to menu button "PDF"
                    click myButton

                    repeat until exists menu 1 of myButton
                        delay 0.02
                    end repeat

                    set myMenu to menu 1 of myButton
                    set myMenuItem to menu item "Save as PDF" of myMenu
                    click myMenuItem

                    repeat until exists sheet 1
                        delay 0.02
                    end repeat

                    set saveSheet to sheet 1
                    tell saveSheet
                        set value of first text field to fileName
                        keystroke "g" using {command down, shift down}

                        repeat until exists sheet 1 of saveSheet
                            delay 0.02
                        end repeat

                        set goDialogue to sheet 1 of saveSheet

                        tell goDialogue
                            set value of first combo box to outputFolder
                            click button "Go"
                        end tell

                        click button "Save"
                    end tell
                end tell

                repeat while printWindow exists
                    delay 0.02
                end repeat
            end tell
        end tell
    end repeat
end tell