Come introdurre un oggetto lista che è memorizzato in un file .txt in un AppleScript?

Ovviamente, non conosco la portata totale di ciò che stai facendo o il modo in cui hai codificato altre cose, dato che non hai fornito tutti i dettagli e il codice, tuttavia, avrei adottato un approccio diverso.

Ho scaricato il Moby Thesaurus dalla pagina collegata nel tuo domanda e ha preformato le seguenti azioni su di esso.

1. Estrai il contenuto del file mthes.tar.Z .
2. Ha aperto il file ./mthes/mobythes.aur in TextWrangler e notato due cose da cambiare.
   • Cambia le terminazioni di linea da Classic Mac (CR) a Unix (LF).
   • Rimosse le virgole finali indesiderate da 6 righe.

Si noti che mentre potevo apportare queste modifiche in TextWrangler, tuttavia preferisco usare Terminal, e lo facevo usando il seguente comando:

tr "\r" "\n" < mobythes.aur | sed -E 's/[,]{1,}$//' > mobythes.txt

Che ha richiesto, ma letteralmente, un secondo da fare (come ho effettivamente preceduto il comando precedente con time , per curiosità). Con il file mobythes.aur che è stato ora elaborato, salvato in mobythes.txt e copiato nella mia cartella Documenti, userò questo nuovo semplice file CSV così com'è, per interrogare la stringa di ricerca per una corrispondenza con il primo campo di ogni record e restituisce il record, senza il primo campo, come elenco da scegliere in AppleScript. Ho trovato questo metodo estremamente veloce, mentre cercavo lo "zoom" dell'ultimo record nel file CSV, ci volle un secondo per tornare e creare l'elenco per quel record al volo.

In AppleScript Editor utilizzo il seguente codice per testare il file CSV semplice come un singolo file contenente le 30.260 linee con 2,5 milioni di sinonimi e parole correlate.

set AppleScript's text item delimiters to ""
set theMobyThesaurus to POSIX path of (path to documents folder) & "mobythes.txt"

set theSearchString to the text returned of (display dialog "Find synonyms for:" default answer "" buttons {"Cancel", "Search"} default button 2 with title "Search Moby Thesaurus")

if theSearchString is not equal to "" then

    try
        set theSearchResults to (do shell script "grep -i -m 1 '^" & theSearchString & ",' " & theMobyThesaurus)
    on error
        display dialog "No match for \"" & theSearchString & "\" available." buttons {"OK"} default button 1
        return
    end try

    if theSearchResults is not equal to "" then
        set AppleScript's text item delimiters to ","
        set theSynonymsList to items 2 thru -1 of text items of theSearchResults as list
        set AppleScript's text item delimiters to ""

        choose from list theSynonymsList with prompt "Choose a synonym for: " & linefeed & theSearchString
        if the result is not false then
            set theChosenWord to (item 1 of the result)
        end if
    end if

end if

In questo esempio, supponendo che sia stata effettuata una corrispondenza di ricerca e nulla è stato annullato, la variabile theChosenWord ora contiene ciò che è stato scelto dall'elenco visualizzato e può essere ulteriormente elaborato come necessario / desiderato.

Si noti che questo è chiaramente un codice di esempio a scopo di test e dovrà essere adattato allo scenario del caso d'uso, incorporando la gestione degli errori appropriata, se necessario.

Credo che questo sarà il modo più veloce lasciando il Moby Thesaurus come un singolo file CSV, ed è probabilmente più veloce di qualsiasi altro metodo tu abbia provato fino ad ora.

Avevo escogitato una soluzione prima che user3439894 avesse pubblicato la risposta.

Nonostante la soluzione user3439894 sia superiore alla mia soluzione in ogni modo, immagino che possa anche pubblicare il mio codice, se non altro per sottolineare il tempo di risposta veloce della soluzione user3439894 .

Rettifiche file:

Ecco le due modifiche che ho apportato al file sorgente, mobythes.aur , per la mia soluzione:

1. Ho convertito il file .aur in un file .txt, semplicemente rinominando l'estensione del file in Finder.

2. Ho inserito (1) il ritorno a capo prima del primo carattere del file .txt (nel caso in cui l'utente cerchi sempre la prima voce del thesaurus, cioè a cappella ).

Mi sono reso conto che stavo abbaiando dall'albero sbagliato nel mio post originale - non c'è bisogno (o beneficio, in realtà) di pre-formattare il contenuto del file .txt nel formato list di AppleScript, all'interno del file stesso. Quindi, non ho modificato la struttura del delimitatore originale del file (nel modo in cui l'avevo fatto nel mio post originale).

Il mio codice:

display dialog "Find synonyms of:" default answer ""
set theSearchQuery to text returned of the result

-- Referencing the default delimiters of the "mobythes.txt" file:
set theOuterListDelimiter_oneCarriageReturn to (ASCII character 13)
set theInnerListDelimiter_oneComma to ","

set theSearchQueryAsAThesaurusEntry to (theOuterListDelimiter_oneCarriageReturn & theSearchQuery & theInnerListDelimiter_oneComma)

set theThesaurusAsString to (read POSIX file "/Users/Me/Desktop/mobythes.txt")

if theThesaurusAsString contains theSearchQueryAsAThesaurusEntry then

    set theSynonymsAsText to extractBetween(theThesaurusAsString, theSearchQueryAsAThesaurusEntry, theOuterListDelimiter_oneCarriageReturn)
    set theSynonymsInList to splitStringIntoList(theSynonymsAsText, theInnerListDelimiter_oneComma)

    choose from list theSynonymsInList
else
    display dialog "No thesaurus entry exists for \"" & theSearchQuery & "\"!"
end if


-- Subroutines:

to extractBetween(SearchText, startText, endText)
    --  Source: http://macscripter.net/viewtopic.php?id=24725
    set tid to AppleScript's text item delimiters -- save them for later.  
    set AppleScript's text item delimiters to startText -- find the first one.  
    set endItems to text of text item -1 of SearchText -- everything after the first.  
    set AppleScript's text item delimiters to endText -- find the end one.  
    set beginningToEnd to text of text item 1 of endItems -- get the first part.  
    set AppleScript's text item delimiters to tid -- back to original values.  
    return beginningToEnd -- pass back the piece.  
end extractBetween

on splitStringIntoList(theString, theDelimiter)
    -- Source: http://erikslab.com/2007/08/31/applescript-how-to-split-a-string/
    -- save delimiters to restore old settings:
    set oldDelimiters to AppleScript's text item delimiters
    -- set delimiters to delimiter to be used:
    set AppleScript's text item delimiters to theDelimiter
    -- create the array:
    set theArray to every text item of theString
    -- restore the old setting:
    set AppleScript's text item delimiters to oldDelimiters
    -- return the result:
    return theArray
end splitStringIntoList

Confronto delle prestazioni in runtime:

Per pura curiosità, ho condotto uno "shoot-out" dei tempi di esecuzione tra l'approccio user3439894 e il mio approccio.

Ho commentato ogni dialogo in entrambe le nostre soluzioni. Ho impostato il termine di ricerca del test come stringa fissa, "planet" .

Inserimento time osascript /Users/Me/Desktop/MyOriginalSolution.scpt in Terminal.app restituito:

real    0m1.257s
user    0m0.728s
sys     0m0.409s

Inserimento time osascript /Users/Me/Desktop/user3439894Solution.scpt restituito:

real    0m0.250s
user    0m0.193s
sys     0m0.030s

In base a questo test, la soluzione user3439894 è oltre 5 volte più veloce della mia, con una differenza di 1.007 secondi.