C'è un modo per non richiedere una password per il login quando sono a casa ma ne richiedo uno ovunque

Ho configurato il mio sistema per fare qualcosa di simile a quello che stai cercando di fare. Sebbene io personalmente non disattivi mai la mia password di accesso (non consiglio mai di farlo per diversi motivi), cambio alcune delle mie impostazioni di sicurezza per la mia rete domestica locale rispetto a quando sono lontano da casa.

Per prima cosa, vorrai ottenere e installare ControlPlane (che NON ho testato con El Capitan). Questo componente aggiuntivo ti consente di modificare diverse impostazioni sul tuo Mac in base alle informazioni sulla posizione che può ricavare da " fonti di prova ". Ha anche un sacco di funzioni integrate, è AppleScriptable e < a href="https://github.com/dustinrue/ControlPlane"> open source .

Una volta installato ControlPlane, dovrai creare un AppleScript che ti consenta di disabilitare o abilitare il login della password in base alle informazioni sulla posizione.

L'AppleScript che crei potrebbe essere diverso a seconda del sistema operativo Mac in uso (nel tuo caso El Capitan). Ma sarà simile allo script che ho creato su OS X 10.9.5 per fare quello che vuoi.

NOTA 1: questo script attiva solo le impostazioni trovate su Security & Privacy, NON ha alcuna comprensione delle informazioni sulla posizione. Probabilmente vorrai creare una versione di questo AppleScript per ogni posizione identificata da ControlPlane e modificarla di conseguenza.

NOTA 2 : questo script richiede all'utente di inserire due volte la propria password amministrativa quando disabilita le impostazioni di login e salvaschermo della password. Non conosco un modo per aggirare questo, a meno che non si desideri eseguire il drop down e fare lo scripting di shell da ControlPlane, o aggiungere la password nell'AppleScript e averlo digitare per voi.

NON GARANTISCO O GARANTISO QUESTO SCRIPT! UTILIZZO A TUO RISCHIO PROPRIO NON HO PROVATO CON EL CAPITAN.

-- !!! USE THIS SCRIPT AT YOUR OWN RISK !!!
-- !!! NO IMPLIED OR EXPLICIT GUARANTEES OR WARRANTIES ARE MADE !!!
-- USE OF THIS SCRIPT IS NOT GUARANTEED TO WORK ON ALL OS VERSIONS!

-- An AppleScript to Disable and Enable automatic login and sleep/screen saver password request.
-- This script may require the user to enter their administrative password twice when disabling.
-- This script ONLY toggles the settings found on the Security & Privacy page.

tell application "System Preferences"
    activate
    set current pane to pane id "com.apple.preference.security"
    delay 1
    tell application "System Events"
        tell process "System Preferences"
            click menu item "Security & Privacy" of menu "View" of menu bar 1
            delay 0.5

            -- Check to see if the System Prefs are locked and editing is disabled.
            if title of checkbox 1 of window 1 is "Click the lock to make changes." then
                click checkbox 1 of window 1
                repeat until checkbox "Click the lock to prevent further changes." of window 1 exists
                    delay 0.1
                end repeat
            end if

            -- This should enable or disable "Disable automatic login"
            click checkbox "Disable automatic login" of tab group 1 of window 1
            repeat until not (exists sheet 1 of window 1)
                delay 0.1
            end repeat
            delay 0.5

            -- This should enable or disable "Require password after sleep or screen saver begins"
            click checkbox 1 of tab group 1 of window 1
            delay 0.25
            repeat until not (exists sheet 1 of window 1)
                click button "Turn Off Screen Lock" of sheet 1 of window 1
            end repeat
            delay 0.25
            -- BE CARFULE IF YOU CHANGE THIS AS IT COULD MODIFY YOUR KEYCHAIN!!!
            repeat until not (exists sheet 1 of window 1)
                click button "Keep Using Keychain" of sheet 1 of window 1
            end repeat

        end tell
    end tell
    tell application "System Preferences" to quit
end tell

Se utilizzi questo script come app AppleScript ASSICURA SICURO che le tue impostazioni di accessibilità siano attivate, altrimenti non funzionerà.