Come posso modificare la lingua per la dettatura al volo?

Naviga le tue risposte
4

Con l'inglese che non è la mia prima lingua, di solito ho bisogno del supporto per almeno due lingue quando uso funzioni come la correzione automatica e la dettatura.

È possibile alternare la lingua utilizzata per la dettatura tramite una scorciatoia?

A partire da ora, devo sempre navigare manualmente tra i menu nelle Preferenze di Sistema che, se non del tutto convenienti. Ho provato a vedere se ci sono azioni predefinite in Automator, ma non ne trovo nessuna.

    
posta gentmatt 03.08.2012 - 21:42
fonte

6 risposte

4

Potresti modificare gli elenchi di proprietà che memorizzano le impostazioni e riaprire il processo DictationIM: 

#!/bin/bash

k="com.apple.speech.recognition.AppleSpeechRecognition.prefs DictationIMLocaleIdentifier"
if [[ "$(defaults read $k)" == en-US ]]; then
  defaults write $k fr-FR
  defaults write com.apple.assistant "Session Language" fr-FR
else
  defaults write $k en-US 
  defaults write com.apple.assistant "Session Language" en-US
fi
killall -HUP DictationIM

O usa lo scripting dell'interfaccia utente: 

tell application "System Preferences"
    reveal anchor "Dictation" of pane "com.apple.preference.speech"
end tell
tell application "System Events" to tell process "System Preferences"
    tell pop up button 1 of tab group 1 of window 1
        click
        if value is "English (United States)" then
            click menu item "French" of menu 1
        else
            click menu item "English (United States)" of menu 1
        end if
    end tell
end tell
quit application "System Preferences"

Entrambi gli script sono copiati dalla mia risposta a Come utilizzare applescript per attivare l'impostazione della lingua del nuovo strumento di dettatura (10.8) - Stack Overflow .

    
risposta data 03.08.2012 - 22:45
fonte
2

Non sei sicuro se questo aiuti, ma qualcuno ha sviluppato un "Dictation Switcher", una piccola utility che si trova nella barra dei menu del tuo Mac e rende ancora più semplice l'uso di Dictation. può essere trovato qui: link

Comprendi che hai avuto il piacere di scrivere la tua sceneggiatura ma, nel caso, ho pensato che potesse aiutarti ...: -)

    
risposta data 02.03.2013 - 19:19
fonte
1

Ho trovato un thread in cui era contenuto il seguente codice di applicazione: 

tell application "System Events" to set p to (path to frontmost application) as string
tell application "System Preferences"
    activate
    reveal anchor "Dictation" of pane "com.apple.preference.speech"
end tell
tell application "System Events"
    tell process "System Preferences"
        tell pop up button 1 of tab group 1 of window "Dictation & Speech"
            click
            if (get value of attribute "AXValue") contains "English (United States)" then
                click menu item "German" of menu 1
                say "Dictation set to German"
            else if (get value of attribute "AXValue") contains "German" then
                click menu item "English (United States)" of menu 1
                say "Dictation set to English"
            end if
        end tell
    end tell
end tell
quit application "System Preferences"
activate application p

L'ho provato e funziona. Tutto quello che devi fare è cambiare "tedesco" nella lingua che preferisci.

Inoltre, posso suggerire un'applicazione chiamata FastScripts , che consente di eseguire il applescript dal menu principale barra o da una scorciatoia da tastiera.

Spero che questo abbia risolto il tuo problema!

    
risposta data 03.08.2012 - 22:21
fonte
1

controlla questo link è molto bello. Spero che questo aiuto

    
risposta data 30.12.2012 - 22:43
fonte
1

Su OSX El Capitan ho avuto difficoltà a far funzionare lo script con user495470 e allo stesso modo con il codice di pasawaya. Ho finito per modificare il codice da pasawaya per includere: 

repeat until exists tab group 1 of window "Dictation & Speech"
end repeat

Ecco lo script completamente modificato che funziona perfettamente per me: 

tell application "System Events" to set currentWindow to (path to frontmost application) as string
tell application "System Preferences"
    reveal anchor "Dictation" of pane "com.apple.preference.speech"
end tell
tell application "System Events"
    tell process "System Preferences"
        repeat until exists tab group 1 of window "Dictation & Speech"
        end repeat
        tell pop up button 1 of tab group 1 of window "Dictation & Speech"
            click
            if (get value of attribute "AXValue") contains "English" then
                click menu item "Danish (Denmark)" of menu 1
                say "Dictation Danish"
            else if (get value of attribute "AXValue") contains "Danish" then
                click menu item "English (United Kingdom)" of menu 1
                say "Dictation English"
            end if
        end tell
    end tell
end tell
quit application "System Preferences"
activate application currentWindow
    
risposta data 30.10.2016 - 22:53
fonte
0

Bene, quando voglio cambiare le lingue, faccio semplicemente clic sul nome della lingua corrente nel piccolo widget di dettatura e ottengo un menu:

    
risposta data 19.11.2017 - 02:26
fonte

Leggi altre domande sui tag

Ripristino di una scheda SD utilizzando un DMG multi-partizionato Come posso estrarre il programma di installazione di Mountain Lion dalla partizione di ripristino