Come si mostrano solo gli album completi in iTunes 11?

Non c'è modo di farlo, purtroppo. Questo suggerimento mostra un AppleScript che può creare playlist da tutti gli album completi, ma se hai molti album , potrebbe essere travolgente.

Crea una playlist intelligente con il seguente filtro: i commenti contengono l'album completo. Per ogni album che voglio aggiungere, faccio clic su Ottieni informazioni e aggiungo Album completo al campo dei commenti

Non puoi. Scrivi un suggerimento ad Apple a: link

È possibile creare una playlist che contenga tutti gli album completi nella libreria utilizzando AppleScript. Il codice seguente è solo una piccola modifica allo script collegato nella risposta di Kirk in modo che crei una playlist invece di una per album. È lento (richiede forse 5 minuti per scorrere la mia libreria) ed è molto sensibile a qualsiasi inesattezza dei metadati, ma funziona per me.

-- Creates one playlist of all full albums you have in iTunes
-- Set the playlistPrefix and playlistSuffix as desired before running

-- Original script by duozmo on Ask Different
-- http://hints.macworld.com/article.php?story=20130201061128257
-- http://apple.stackexchange.com/a/77626

-- Based on code by Brad Campbell
-- http://www.bradcampbell.com/2009/05/26/make-a-whole-album-playlist-in-itunes/

tell application "iTunes"
    set albumPlaylistName to "Full Albums"
    -- Create playlist
    if user playlist albumPlaylistName exists then
        try
            delete tracks of user playlist albumPlaylistName
        end try
    else
        make new user playlist with properties {name:albumPlaylistName}
    end if

    set albumBuckets to {} as list
    set allSongs to (every track of library playlist 1 whose enabled is true and podcast is false and kind contains "audio") as list

    -- Find all partial albums in iTunes
    repeat with currentTrack in allSongs
        set albumName to album of currentTrack as text
        set artistName to artist of currentTrack as text

        -- First check for missing values, then perform integer comparison
        -- Zero is on the left to force interger type coercion, just in case
        if album of currentTrack is not missing value and 0 is less than length of albumName then
            if artist of currentTrack is not missing value and 0 is less than length of artistName then
                if track number of currentTrack is not missing value and 0 is less than track number of currentTrack then
                    if track count of currentTrack is not missing value and 0 is less than track count of currentTrack then
                        if albumBuckets does not contain album of currentTrack then
                            copy album of currentTrack to the end of albumBuckets
                        end if
                    end if
                end if
            end if
        end if

    end repeat

    repeat with currentAlbum in albumBuckets
        set albumSongs to (every track of library playlist 1 whose album is currentAlbum)
        set firstTrack to first item of albumSongs

        -- Filter album list to act only on full albums
        if (count of albumSongs) is equal to track count of first item of albumSongs and 1 is less than (count of albumSongs) then
            -- This is a full album, construct the playlist

            -- Sort tracks by track number
            set albumSongsSorted to {} as list
            repeat with i from 1 to (count of albumSongs)
                repeat with trk in albumSongs
                    if track number of trk is i then
                        set nextSong to trk
                        copy nextSong to the end of albumSongsSorted
                    end if
                end repeat
            end repeat

            try
                repeat with trk in albumSongsSorted
                    duplicate trk to user playlist albumPlaylistName
                end repeat
            end try
        end if
    end repeat

    display dialog albumPlaylistName & " playlist created!"
end tell

Un'altra opzione potrebbe essere quella di utilizzare lo script Doug's Random Full Albums se vuoi semplicemente iTunes per agisci come un caricatore CD in modalità album shuffle.