Come posso associare i file URL con un browser specifico in Snow Leopard?

Per quanto ne so, non c'è modo di associare i file .webloc con un'applicazione specifica. La tua migliore scommessa sarebbe probabilmente quella di usare un AppleScript.
Ho creato un piccolo script che ti consente di generare piccole applicazioni AppleScript che si aprono nel browser che selezioni al momento della creazione (OmniWeb, Safari o Chrome).

Puoi scaricare lo script qui , o compilare tu stesso dal codice qui sotto.

set theURL to text returned of (display dialog "What URL would you like to bookmark?" with title "Enter URL" default answer "http://")
set theApp to (choose from list {"OmniWeb", "Safari", "Chrome"} with prompt "Which application would you like to associate with the bookmark?" with title "Select Application") as string
set theName to text returned of (display dialog "What would you like to name the bookmark?" with title "Enter Name" default answer "")
set theFolder to choose folder with prompt "Where would you like to save the bookmark?"

if theApp is "OmniWeb" then
    set theScript to "tell application \"OmniWeb\"
    activate
    try
        set theTab to make new tab at end of front browser with properties {address:\"" & theURL & "\"}
        set active tab of front browser to theTab
    on error
        make new browser with properties {address:\"" & theURL & "\"}
    end try
end tell"
else if theApp is "Safari" then
    set theScript to "tell application \"Safari\"
    activate
    try
        set theTab to make new tab at end of tabs of front window
        set the URL of theTab to \"" & theURL & "\"
    on error
        make new document
        set theTab to tab 1 of front window
        set the URL of theTab to \"" & theURL & "\"
    end try
    set current tab of front window to theTab
end tell"
else if theApp is "Chrome" then
    set theScript to "tell application \"Google Chrome\"
    activate
    if (count of windows) = 0 then
        make new window
        set URL of tab 0 of front window to \"" & theURL & "\"
    else
        set URL of (make new tab at end of tabs of front window) to \"" & theURL & "\"
    end if
end tell"
end if

tell application "AppleScript Editor"
    set theDoc to make new document with data theScript
    save theDoc as "application" in ((theFolder as string) & theName & ".app")
end tell

In esecuzione che ti chiederà l'URL, il browser con cui vuoi che venga aperto e la posizione in cui salvare il "segnalibro".

Puoi metterlo nella cartella Applicazioni o Script per un facile accesso e invocarlo ogni volta che desideri salvare un URL.

Devi creare uno script di Automator con questi elementi: (e salva come app)

• RunShellScript - > %codice%
• Pausa (2 secondi)
• RunShellScript - > %codice%

Puoi leggere questo articolo su Macworld: link

Ma la carne della correzione dalla sezione Soluzione alternativa è:

Control-click on the file in question, then hold down the Option key, then select Always Open With, and choose the desired application from the (potentially huge) list of alternatives. You’ll have to do this every time you create a new file; there’s no way to set the creating application as the default opening application.

Sono sfortunatamente su Windows al lavoro, quindi non posso confermare questa correzione. Ma sembra che sia la strada da percorrere.

La soluzione che stai cercando non è semplice. Mi è venuta in mente un'idea che ho postato in: associare l'applicazione a un file con nomi particolari (anziché suffisso) . Non sono uno sviluppatore Apple professionale, né conosco i dettagli complessi del sistema operativo. Ma come programmatore occasionale, penso che sarebbe una soluzione possibile.

Quanto sopra se vuoi continuare ad usare .webloc , naturalmente. Quello che vorrei fare è però il seguente:

1. Modifica l'estensione di quei particolari file di segnalibri che vuoi aprire con una particolare applicazione a .url .
2. Associa quelli con il browser desiderato.

A partire da macOS 10.12 Sierra, .webloc e .url file entrambi aperti nel browser predefinito. Possono essere aperti in un altro browser utilizzando il menu "Apri con", ma il valore predefinito non può essere modificato per file o per estensione.

La soluzione che ho trovato è creare un'applicazione AppleScript:

1. Apri l'applicazione Script Editor (il successore dell'app AppleScript)

2. Incolla questo codice:

   tell application "Safari" to open location "https://apple.stackexchange.com/"

   (Cambia l'URL di quello che ti serve)

3. File | Salva come con Formato file impostato su "Script"

   • Questo è un file binaryScript che verrà riaperto nello Script Editor
   • Può essere modificato ed eseguito dall'interno dell'editor, ma non può essere eseguito dal finder

4. File | Esporta con Formato file impostato su "Applicazione"

   • Questo è un pacchetto di applicazioni che verrà eseguito
   • Può essere eseguito dal finder, ma non può essere aperto nell'editor

Questo approccio funziona per creare un "link" nel mirino che si aprirà in Safari, ma ha alcuni problemi:

• Non è portabile (ho anche salvato un file .url )
• Sono 2 (o 3) file in cui preferirei 1
• La riapertura dello script (dal punto 3) nell'editor avvia anche Safari (senza aprire l'URL)

Nel mio caso - l'apertura di una vecchia applet Java aziendale che utilizza solo il browser come un launcher - lascia anche Safari aperto su una pagina vuota inutile.

Sono sicuro che questo potrebbe anche essere fatto con uno script di shell, che potrebbe almeno portarlo a 1 (o 2) file.