È possibile associare il mio Mac OSX Dictionary.app a Google Traduttore?

Purtroppo non sembra possibile, o almeno semplice. In alternativa, potresti prendere in considerazione la creazione di un OS Servizio che apre Google Traduttore in una finestra del browser, per qualsiasi parola o frase evidenziata che hai selezionato.

Se ciò sembra adatto, segui la procedura seguente:

Creazione di un servizio di traduzione

• Apri l'app Automator dalla tua cartella Applications
• Seleziona Service come tipo di documento e fai clic su Choose
• Nella finestra visualizzata, fai clic sul campo di ricerca e digita "AppleScript"
• Trascina l'azione Run AppleScript dall'elenco a sinistra nell'area denominata "Trascina azioni o file qui per creare il tuo flusso di lavoro"

Copia lo script qui sotto e incollalo nell'azione Run Applescript :

on run {input, parameters}
    set phrase to input as string
    set phrase to quoted form of phrase

    set ui_lang to "en"
    set from_lang to "en"
    set to_lang to "zh-CN"

    do shell script "open 'https://translate.google.com/?hl='" & ui_lang & "'&sl='" & from_lang & "'&tl='" & to_lang & "'&text='" & phrase
end run

La tua finestra dovrebbe apparire come la seguente:

Cisonotrevalorichepotrestivolercambiarenelloscriptprecedente:

• ui_lang-lalinguautilizzataperl'interfacciadipagina
• from_lang-lalinguadiorigine
• to_lang-lalinguadidestinazione

Modificaunoopiùdiquestiperottenerelatraduzionedesiderata.Pertrovareiparametrilinguisticicorretti,consultail Riferimento della lingua . Nell'esempio sopra en si riferisce a English e zh-CN a Cinese (semplificato).

Dopo aver apportato le modifiche, fai clic su File > Save... e nel pannello che appare digita un nome adatto (ad esempio Translate English to Chinese ).

Utilizzo del servizio di traduzione

Dopo aver salvato il tuo flusso di lavoro sopra, puoi utilizzare il tuo servizio di traduzione con uno dei seguenti due metodi:

1. Il metodo del menu Servizio

• Evidenzia una parola o una frase in qualsiasi applicazione
• Fai clic sul menu Applicazione a destra dell'icona di Apple (), quindi fai clic su Services e Translate English to Chinese (o sul nome che hai fornito al servizio quando lo salvavi):

2.Ilmetododelmenucontestuale

• Evidenziaunaparolaounafraseinqualsiasiapplicazione
• FaiclicconiltastodestrodelmousesultestoeselezionaServicespoiTranslateEnglishtoChinese(oiltuoserviziopersonalizzatodenominato):

Qualunquesiailmetodocheusi,unafinestradelbrowserdovrebbeapparireconiltestotradotto:

Questo fa tutto come la risposta di soulcake ma se l'URL del traduttore è già presente - carica una nuova traduzione in la stessa scheda

on run {input, parameters}
    set phrase to input as string

    set ui_lang to "en"
    set from_lang to "en"
    set to_lang to "ru"

    set theBaseUrl to "https://translate.google.com/"
    set theUrl to theBaseUrl & "?hl=" & ui_lang & "&sl=" & from_lang & "&tl=" & to_lang & "&text=" & phrase

    tell application "Google Chrome"
        activate

        if (count every window) = 0 then
            make new window
        end if

        set found to false
        set theTabIndex to -1
        repeat with theWindow in every window
            set theTabIndex to 0
            repeat with theTab in every tab of theWindow
                set theTabIndex to theTabIndex + 1
                if theTab's URL starts with theBaseUrl then
                    set found to true
                    exit repeat
                end if
            end repeat

            if found then
                exit repeat
            end if
        end repeat

        if found then
            set URL of theTab to theUrl
            set theWindow's active tab index to theTabIndex
            set index of theWindow to 1
        else
            tell window 1 to make new tab with properties {URL:theUrl}
        end if
    end tell

end run