Potresti utilizzare il seguente AppleScript , salvarlo come applicazione e impostarlo come agente (nessuna icona del dock).

Questo script configurerà una connessione VPN quando non ce n'è. Pertanto, dovrebbe anche riconnettersi subito dopo la connessione. Puoi cambiare l'intervallo per controllare la tua connessione VPN, sono 120 secondi nello script.

on idle
    tell application "System Events"
        tell current location of network preferences
            set myConnection to the service "VPN University"
            if myConnection is not null then
                if current configuration of myConnection is not connected then
                    connect myConnection
                end if
            end if
        end tell
        return 120
    end tell
end idle

Ho spiegato come configurarlo in questa risposta .

Ho apportato alcune modifiche alla risposta fornita, perché se qualcosa vale la pena farlo, vale la pena di farlo. Volevo riconnetterti se la VPN fosse stata abbandonata, ma NON riconnetterei se la VPN fosse intenzionalmente disconnessa. La soluzione che ho trovato è stata efficace e poco elegante.

Per prima cosa ho aggiunto ganci all'avvio e all'arresto di pppd per tenere traccia dello stato della VPN desiderato. Questi file devono essere di proprietà di root e disporre di autorizzazioni di lettura / esecuzione in tutto il mondo ( sudo chmod 755 /etc/ppp/ip-* ).

/ etc / ppp / ip-up:

#!/bin/sh
echo true > /var/run/reconnect_vpn
chmod 644 /var/run/reconnect_vpn

/ etc / ppp / ip-down: per OS X 10.9.5 e versioni precedenti

#!/bin/sh
tail /var/log/ppp.log | grep '\[DISCONNECT\]'
if [ $? == 0 ] ; then
echo false > /var/run/reconnect_vpn
fi

/ etc / ppp / ip-down: per OS X 10.10 e successivi

#!/bin/sh
tail /var/log/ppp.log | grep '\[TERMINATE\]'
if [ $? == 0 ] ; then
echo false > /var/run/reconnect_vpn
fi

Quindi, modificando l'AppleScript di cui sopra, sono stato in grado di controllare la variabile di stato '/ var / run / reconnect_vpn' per determinare se ripristinare la VPN:

on idle
    tell application "System Events"
        tell current location of network preferences
            set myConnection to the service "VPN"
            set startOnLogin to true
            local doReconnect
            try
                set doReconnect to (do shell script "cat /var/run/reconnect_vpn")
            on error errMsg
                set doReconnect to startOnLogin
            end try
            if myConnection is not null and doReconnect then
                if current configuration of myConnection is not connected then
                    connect myConnection
                end if
            end if
        end tell
        return 120
    end tell
end idle

Come prima, cambia la linea set myConnection to the service "VPN" in qualunque sia la tua VPN. Inoltre, all'avvio il file 'reconnect_vpn' non esiste, quindi ho aggiunto un valore booleano (startOnLogin) da utilizzare come predefinito quando il file non è stato trovato. Mi piace iniziare immediatamente, ma se non lo fai, cambiala in falso.

Ho la sensazione che se sei il tipo di persona è questo particolare riguardo al comportamento della VPN, allora sei anche il tipo di persona a cui piace armeggiare fino a trovare una soluzione e quindi questa risposta non ha pubblico. Ma nel caso, eccolo. Spero che aiuti qualcuno.

C'è un'app che si chiama VPN Auto-Connect (Mac App Store link). È $ 0,99.

Una volta avviato, vive nella barra dei menu; quando lo usi per attivare la VPN, monitora un profilo di connessione VPN che hai configurato nel pannello delle preferenze di Rete di OS X e assicurati di rimanere sempre connesso ad esso. L'icona della barra dei menu di VPN Auto-Connect fornisce un elenco di tutte le connessioni VPN che hai definito e ti consente di scegliere a quale connettere sempre.

Una nuova opzione è Monitor VPN disponibile su AppStore. Consente una maggiore personalizzazione, come l'accesso automatico, il ciclismo attraverso connessioni VPN, ecc. Almeno OS X 10.9 Mavericks richiesti.

Script auto-riconnesso qualsiasi servizio VPN eliminato.

Utilizzo rjarvis2010 della soluzione , ma non ero abbastanza felice con esso.

Ho molti servizi VPN a cui mi collego, quindi volevo uno script che ricollegasse automaticamente qualsiasi VPN a cui ero connesso.

on idle
    tell application "System Events"
        tell location "Uni" of network preferences
            -- keep checking for VPN name until a VPN is connected
            set empty to true
            repeat until empty is false
                try
                    -- set variable "myVPN" to the name of the service that is connected and is a VPN
                    set myVPN to get name of first service whose (kind is greater than 11 and kind is less than 17) and connected of current configuration is true
                    set empty to false
                on error
                    set empty to true
                    delay 15
                end try
            end repeat

            -- doReconnect is a file that reads from the ppp.log and contains "true" by default, "false" if the vpn service was manually disconnected recently
            local doReconnect
            set doReconnect to (do shell script "cat /var/run/reconnect_vpn")

            repeat while doReconnect contains "true"
                set ConfProp to get current configuration of service myVPN
                if connected of ConfProp is false then
                    delay 1
                    set doReconnect to (do shell script "cat /var/run/reconnect_vpn")
                    if doReconnect contains "true" then
                        try
                            connect service myVPN
                        on error errorMessage
                        end try
                    else
                        exit repeat
                    end if
                end if
                delay 5
            end repeat
        end tell
    end tell
    return 1
end idle

Per farlo funzionare, devi sostituire

• Uni con qualunque sia il nome della tua posizione

Una volta terminato, salvalo come applicazione e inseriscilo negli elementi di accesso e sei pronto per iniziare.

Inoltre, e questo è importante, è necessario impostare i ganci PPP come descritto in rjarvis2010 soluzione