Crea un nuovo file (.txt) nel Finder: scorciatoia da tastiera

Bene, ecco qui un AppleScript.

Per prima cosa, crea l'AppleScript:

1. Apri Automator
2. Crea un servizio
3. Imposta l'input su nessun input
4. Trascina e rilascia l'elemento del flusso di lavoro Esegui AppleScript nello spazio grigio.
5. Incolla il codice dal basso in AppleScript
6. Salva il flusso di lavoro come Crea nuovo file
   Se hai attivato iCloud Drive, assicurati di salvare il file in Library/Services/ nella cartella Home.

try
  tell application "Finder" to set the this_folder ¬
   to (folder of the front window) as alias
on error -- no open folder windows
  set the this_folder to path to desktop folder as alias
end try

set thefilename to text returned of (display dialog ¬
 "Create file named:" default answer "filename.txt")
set thefullpath to POSIX path of this_folder & thefilename
do shell script "touch \"" & thefullpath & "\""

Per aggiungerlo come scelta rapida:

• Vai a Impostazioni - > Tastiera - > Scorciatoie - > Servizi
• Scorri verso il basso fino a trovare il servizio Crea nuovo file
• Assegna un collegamento ad esso facendo clic sul lato destro nessuno , che diventa un Aggiungi collegamento .
  Fare clic sul pulsante e digitare il collegamento che si desidera utilizzare.
  Io uso ⌘ Comando + ⌥ Opzione + N

Ho creato un AppleScript molto simile a quello di @ YoshiBotX, ma con alcuni miglioramenti.

L'idea è di creare un flusso di lavoro di Automator e assegnargli una scorciatoia usando i seguenti passaggi:

• Apri Automator e crea un servizio ;
• Imposta l'input su nessun input e l'applicazione su Finder.app ;
• Trascina e rilascia l'elemento del flusso di lavoro Esegui AppleScript nello spazio grigio;
• Inserisci il contenuto di questo AppleScript nella casella di testo;
• Salva il flusso di lavoro con un nome ragionevole (come Nuovo file );
• Vai a Impostazioni - > Tastiera - > Scorciatoie - > Servizi e assegnagli un collegamento.

Ora mostriamo l'AppleScript:

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

Per comodità, sto mettendo questo AppleScript in questo GitHub Gist .

Puoi creare autonomamente un servizio di automazione - è piuttosto semplice da fare. Quindi puoi assegnargli una scorciatoia da tastiera per non dover attivare il servizio tramite il menu servizi (che puoi comunque fare).

Apri Automator e seleziona Servizio come tipo di nuovo documento.

Imposta il servizio per non ricevere input in Finder.app e aggiungi l'azione Nuovo documento TextEdit al flusso di lavoro.

Salvailservizio,quindiapriPreferenzedisistema→Tastiera→Scorciatoie→ServiziincuitroveraiilservizioelencatosottoGeneraleconilnomechehaidatoperilservizioquandolohaisalvato.

Aggiungi una scorciatoia da tastiera al servizio selezionando il servizio, quindi fai clic su "aggiungi collegamento".

Qui potresti avere qualche problema se il collegamento è già utilizzato. Quindi, diventa creativo per crearne uno che funzioni per te.

Potresti anche assegnare un collegamento a uno script come questo:

tell application "Finder"
    set selection to make new file at (get insertion location)
end tell

La posizione di inserimento è la destinazione della finestra del Finder in primo piano o del desktop.

apri il terminale e digita

touch filename

o

> filename

Questo è un post di un post che ho fatto l'anno scorso. Ho avuto una buona esperienza con il seguente.

Ci sono due utili utility che puoi scaricare e installare che ti permetteranno di creare un nuovo file di testo (o file RTF) in una cartella attualmente aperta che stai visualizzando usando il Finder.

Le utilità sono chiamate NewTextFileHere e NewRTFHere e possono essere scaricate da

link

Le icone per ciascuna di queste app possono quindi essere incluse in tutte le finestre del Finder.

Proprio quello che stavo cercando, Richard Fuhr. Grazie per questo.

Una nota: il link dell'URL per il NewTextFileHere sembra essere caricato su una pagina vuota. Ma ho fatto una ricerca e ho trovato l'app qui: link

Un'alternativa, se hai già BetterTouchTools (era un'app gratuita, ora ha un pay-what-you -solo modello con un periodo di prova di 30 giorni), puoi trovare l'azione su "Utility Actions > Create New File in Current Folder" che fa esattamente questo, con un pop-up che ti permette di scegliere il nome. Assegna la scorciatoia che vuoi (ho scelto Option + Shift + N) e sei a posto.

Nel caso tu stia utilizzando MacVim c'è un'opzione sotto Finder -> Services per creare un nuovo buffer vim:

HomappatoquestoallascorciatoiaMaiusccmdMinSystemPreferences->Keyboard->Shortcuts: