Qualche gestore di finestre mi consente di far scattare finestre ai lati del display?

Dopo aver testato SizeUp e Breeze, ho deciso che Breeze soddisfa le mie esigenze al meglio. Entrambi consentono di posizionare le finestre a sinistra, a destra o a schermo intero. La funzione che lo ha venduto per me era l'impostazione di una dimensione e amp di default; posizione per un'applicazione e assegnando un tasto di scelta rapida.

SizeUp è esattamente ciò di cui hai bisogno:

SizeUp allows you to quickly position a window to fill exactly half the screen (splitscreen), a quarter of the screen (quadrant), full screen, or centered via the menu bar or configurable system-wide shortcuts (hotkeys). Similar to "tiled windows" functionality available on other operating systems.

Divvy

Divvy is a little menubar app that allows you to automatically resize any active window. Divviy virtually divides your screen into a 6x6 grid. When invoked, Divvy brings up a little HUD in the middle of the screen with this 6x6 grid. Depending on what part of your screen you want to resize your active window, just drag and select those squares on the HUD and the window does the rest. It’s that simple.

ShiftIt (versione originale al link interrotta) lo fa, ed è gratuito e open source.

Modifica: il progetto è ora in GitHub , tuttavia l'ultima versione era nel novembre 2010.

Moom

Ho sentito alcune persone parlare anche di questo:

Do you spend a lot of time moving and zooming windows, so you can better see and work with all the content on your Mac? Instead of doing that work yourself, let Moom handle the task for you.

Se hai un mouse magico o un trackpad magico, BetterTouchTool è migliore in quanto puoi impostare gesti specifici per gestire le finestre. Come un dito sinistro con quattro dita, puoi ridimensionare la finestra a sinistra del 50% dello schermo.

Moom è fantastico. Puoi scattare finestre su: schermo intero, mezzo schermo, quarto schermo. Puoi anche ridimensionare con una griglia. Supporta anche le scorciatoie da tastiera personalizzate.

Personalmente uso SizeUp e Divvy quotidianamente. Se avessi saputo di ShiftIt prima, probabilmente non avrei pagato per SizeUp. Un altro a verificare che non sia stato ancora menzionato è BetterTouchTool , che ha molte altre funzionalità, ma nascosto nelle opzioni avanzate è una bella funzionalità che chiamano "Window Snapping" che scatta la finestra a sinistra oa destra dello schermo quando la trascini di lato. Non ha funzionalità di scorciatoie da tastiera incluse, ma è un bel supplemento per SizeUp e Divvy.

L'ho trovato da una off topic question on Stack Overflow :

C'erano due gestori di Open Source menzionati lì che non si sono mostrati in questo elenco:

• Spettacolo - > link
• Slate - > link (l'installazione richiede lavoro sulla riga di comando)

Altro da App Store

• Slicer - > link

Puoi anche provare Slate che è gratuito e open source.

Potresti anche leggere questo articolo a riguardo.

Ecco un oggetto Applescript che affiancherà tutte le finestre aperte nell'applicazione in primo piano. Aggiungi a ~/Library/Scripts e chiama dal menu Applescript nella barra dei menu. Aggiungi sale a piacere (e gratuito).

--tile windows of frontmost applications in a grid
--this script is useful for
--multiple window chatting
--working side by side of several windows of the same app

--make need to make it as a stay open application later
--for now assume that it is opened and closed per invokation

property horizontalSpacing : 10 -- sets the horizontal spacing between windows
property verticalSpacing : 10 -- sets the vertical spacing between windows
property maxRows : 2
property maxCols : 2

on run {}
    local a
    set userscreen to my getUserScreen()

    --display dialog (getFrntApp() as string)
    try
        set applist to getFrntApp()
        if length of applist = 0 then
            return
        end if
        set a to item 1 of getFrntApp()
    on error the error_message number the error_number
        display dialog "Error: " & the error_number & ". " & the error_message buttons {"OK"} default button 1
    end try

    try
        tileScriptable(a, userscreen)
    on error the error_message number the error_number
        --display dialog "Error: " & the error_number & ". " & the error_message buttons {"OK"} default button 1
        try
            tileUnscriptable(a, userscreen)
        on error the error_message number the error_number
            display dialog "Error: " & the error_number & ". " & the error_message buttons {"OK"} default button 1
        end try
    end try

end run

on tileScriptable(a, screen)
    local i, c
    set i to 1
    tell application named a
        set theWindows to every window of application a whose visible is true and floating is false and ¬
            modal is false -- and miniaturized is false
        set c to count theWindows
        if c = 0 then
            return
        end if
        set tiles to calTileBounds(c, screen, 1)
        repeat with theWindow in theWindows
            my tileScriptableWindow(a, theWindow, item i of tiles)
            set i to i + 1
        end repeat
    end tell
end tileScriptable

on tileUnscriptable(a, screeninfo)
    -- unscriptable app
    local i, c
    set i to 1
    tell application "System Events"
        set theWindows to (every window of application process a)
        --set theWindows to my filterUnscriptableInvisible(theWindows)

        set c to count theWindows

        if c = 0 then
            return
        end if

        --display dialog screeninfo as string giving up after 5
        set tiles to my calTileBounds(c, screeninfo, 1)
        repeat with theWindow in theWindows
            --display dialog (class of visible of theWindow)
            my tileUnScriptableWindow(a, theWindow, item i of tiles)
            set i to i + 1
        end repeat

    end tell
end tileUnscriptable

on filterUnscriptableInvisible(ws)
    -- filter out from ws windows that are docked    
    set newws to {}
    set docklist to getNamesDocked()
    --display dialog (docklist as string)
    repeat with theWindow in ws
        if name of theWindow is not in docklist then
            set end of newws to theWindow
        end if
    end repeat

    --display dialog (count newws)
    return newws
end filterUnscriptableInvisible

on getNamesDocked()
    tell application "System Events" to tell process "Dock"'s list 1
        set l to name of UI elements whose subrole is "AXMinimizedWindowDockItem"
    end tell

    return l
end getNamesDocked

on tileScriptableWindow(a, w, bound)
    tell application a
        set bounds of w to bound
    end tell
end tileScriptableWindow

on tileUnScriptableWindow(a, w, bound)
    tell application "System Events"
        --display dialog (count position of w)
        set AppleScript's text item delimiters to " "

        set position of w to {(item 1 of bound), (item 2 of bound)}

        -- why the -5?
        set size of w to {(item 3 of bound) - (item 1 of bound) - 5, ¬
            (item 4 of bound) - (item 2 of bound) - 5}
        --display dialog (count properties of w)
    end tell
end tileUnScriptableWindow

on calTileBounds(nWindows, screen, direction)
    -- return a list of lists of window bounds
    -- a simple tile algo that tiles along direction (current only 1=horizontal)

    local nrows, nColumns, irow, icolumn, nSpacingWidth, nSpacingHeight, nWindowWidth, nWindowHeight
    set {x0, y0, availScreenWidth, availScreenHeight} to screen
    set ret to {}

    set nrows to (nWindows div maxCols)
    if (nWindows mod maxCols) ≠ 0 then
        set nrows to nrows + 1
    end if

    if nrows < maxRows then
        set nSpacingHeight to (nrows - 1) * verticalSpacing
        set nWindowHeight to (availScreenHeight - nSpacingHeight) / nrows
    else
        set nSpacingHeight to (maxRows - 1) * verticalSpacing
        set nWindowHeight to (availScreenHeight - nSpacingHeight) / maxRows
    end if

    repeat with irow from 0 to nrows - 1
        if nrows ≤ maxRows and irow = nrows - 1 then
            set nColumns to nWindows - irow * maxCols
        else
            set nColumns to maxCols
        end if
        set nSpacingWidth to (nColumns - 1) * horizontalSpacing
        set nWindowWidth to (availScreenWidth - nSpacingWidth) / nColumns
        set nTop to y0 + (irow mod maxRows) * (verticalSpacing + nWindowHeight)
        --display dialog "Top: " & nTop buttons {"OK"} default button 1
        repeat with icolumn from 0 to nColumns - 1
            set nLeft to x0 + (icolumn) * (horizontalSpacing + nWindowWidth)
            set itile to {¬
                nLeft, ¬
                nTop, ¬
                nLeft + nWindowWidth, ¬
                nTop + nWindowHeight}
            set end of ret to itile
            --display dialog item 3 of itile as string
            --set itile to {x0 + (icolumn - 1) * wgrid, y0, wgrid, hgrid}
            --set item 3 of itile to ((item 1 of itile) + (item 3 of itile))
            --set item 4 of itile to ((item 2 of itile) + (item 4 of itile))
        end repeat
    end repeat

    return ret
end calTileBounds



on getFrntApp()
    tell application "System Events" to set frntProc to ¬
        name of every process whose frontmost is true and visible ≠ false
    return frntProc
end getFrntApp

on getUserScreen()
    -- size of the menubar
    tell application "System Events"
        set {menuBarWidth, menuBarHeight} to size of UI element 1 of application process "SystemUIServer"
        --display dialog "Menubar width: " & menubarWidth & ", height: " & menubarHeight
        set dockApp to (application process "Dock")
        set {dockWidth, dockHeight} to size of UI element 1 of dockApp
        --display dialog "Dock width: " & dockWidth & ", height: " & dockHeight
        set dockPos to position of UI element 1 of dockApp
        --display dialog "Dock x: " & (item 1 of dockPos) & ", y: " & (item 2 of dockPos)
    end tell

    -- size of the full screen
    (*
   {word 3 of (do shell script "defaults read /Library/Preferences/com.apple.windowserver | grep -w Width") as number, ¬
       word 3 of (do shell script "defaults read /Library/Preferences/com.apple.windowserver | grep -w Height") as number}
   *)
    tell application "Finder"
        set screenSize to bounds of window of desktop
        set screenWidth to item 3 of screenSize
        set screenHeight to item 4 of screenSize
    end tell
    --display dialog "Screen width: " & screenWidth & ", height: " & screenHeight

    -- by default, set the available screen size to the full screen size
    set availableWidth to screenWidth
    set availableHeight to screenHeight - menuBarHeight
    set availableX to 0
    set availableY to menuBarHeight

    --determine the userscreen origin and size

    -- case 0: hidden dock
    -- if (item 1 of dockPos < 0 or item 1 of dockPos ≥ screenHeight) then
    -- no need to change anything
    -- end if

    -- case 1: bottom dock
    if ((item 2 of dockPos) + dockHeight = screenHeight) then
        set availableHeight to availableHeight - dockHeight
    end if

    -- case 2: left dock
    if (item 1 of dockPos = 0) then
        set availableWidth to availableWidth - dockWidth
        set availableX to dockWidth
    end if

    -- case 3: right dock
    if ((item 1 of dockPos) + dockWidth = screenWidth) then
        set availableWidth to availableWidth - dockWidth
    end if

    return {availableX, availableY, availableWidth, availableHeight}
end getUserScreen

Fonte: MacScripter tramite Google

Da quello che ho visto e sentito, Cinch è un'ottima applicazione per portare la gestione delle finestre di Windows 7 su Mac OS X .

Prima di tutto, se la libertà è importante per te, scarica ShiftIt.

Se la convenienza di un mouse è importante per te, prendi Cinch. È nel Mac App Store.

Infine se hai un Macbook o un Magic Trackpad, prendi JiTouch. Ti permetterà di assegnare un gesto a molte, molte cose; uno dei quali è a schermo intero, metà sinistra e metà destra. Controllalo seriamente se ti piacciono i gesti anche un po '. È come avere un mouse con più di 100 pulsanti. JiTouch

MercuryMover

Potresti anche guardare MercuryMover, che ti offre una gamma di strumenti per spostare le finestre sotto una serie di mappature di tastiera. Usavo molto questo quando ero in difficoltà con uno schermo di un piccolo laptop, e puoi farlo girare una finestra sul bordo di uno schermo, ecc. Più strettamente mappa la funzionalità del menu di sistema 'sposta' che ottieni in Windows normale ' finestre.

Sto usando Magnet, è disponibile su AppStore

link

Per quanto riguarda la tua domanda, vuoi incollare la finestra sul bordo dello schermo, in modo che il lato della finestra si trovi direttamente sul bordo dello schermo. Questo è ora possibile su macOS Sierra (10.12) in modo nativo.

Tutto quello che devi fare è spostare la finestra che vuoi posizionare (facendo clic e trascinando la parte superiore della finestra) sul lato che vuoi mantenere. Devi farlo lentamente, altrimenti non funzionerà. Dopo aver trascinato la finestra sul bordo, rimarrà un po 'ferma e questo è il momento in cui dovresti fermarti.