AppleScript per il riavvio su Bootcamp?

Question

AppleScript per il riavvio su Bootcamp?

#1 da (0 voti)
#2 da (0 voti)

-1

Ho provato ad usare un AppleScript per riavviare Windows Non sta andando bene, però, come quando l'ho provato la prima volta, una schermata bianca appariva all'avvio e non andava via. Un reset hardware riavviato su Yosemite. Ho salvato questo script come applicazione e nel mio Dock per il riavvio istantaneo, ma è stato deludente.

Ecco lo script:

set adminpass to "MYPASSWORDWENTHERE"

tell application "Finder"
    set iconPath to (get name of startup disk) & ":Applications:Utilities:Boot Camp Assistant.app:Contents:Resources:DA.icns" as alias
end tell

set askRestart to display dialog "Restart in Windows?" buttons {"Cancel", "Restart"} default button 1 with icon iconPath
set doRestart to button returned of askRestart

if doRestart is equal to "Cancel" then
    quit
end if

if doRestart is equal to "Restart" then
    do shell script "bless -mount /Volumes/BOOTCAMP/ -legacy -setBoot -nextonly; shutdown -r now" password adminpass with administrator privileges
end if

Qualcuno può aiutarmi a far funzionare questa cosa?

yosemite bootcamp applescript

posta JesusGeek35 26.03.2015 - 02:48

fonte

2 risposte

Leggi altre domande sui tag yosemite bootcamp applescript

Mac mini come "router" Disabilita Siri sostituendolo con Controllo vocale in IOS 7+

score 0 · Answer 1

do shell script "bless -mount /Volumes/WINDOWS/ -legacy -setBoot -nextonly" with administrator privileges
do shell script "shutdown -r now" with administrator privileges

Sostituisci WINOWS con il nome della partizione bootcamp.

Fonte: Lifehacker.com

score 0 · Answer 2

Ho provato questo usando Yosemite e funziona. Presumo che stai facendo un avvio del BIOS per Windows. Se si sta eseguendo un avvio EFI, probabilmente questo script non funzionerà. L'avvio del BIOS è il modo tradizionale in cui BootCamp installa Windows su Mac. Ho aggiunto un pulsante aggiuntivo per consentire la modifica del sistema operativo predefinito su Windows.

Sei consapevole del fatto che puoi tenere premuto il tasto alt / option all'avvio per selezionare il sistema operativo da cui iniziare? Suppongo anche che tu sappia che il sistema operativo di avvio predefinito può essere selezionato dalle Preferenze di Sistema in OS X e dal Pannello di controllo in Windows?

Puoi anche installare il REFINd gestore di avvio gratuito. Questo prodotto può produrre un menu di avvio opzionale ogni volta che si avvia (o si riavvia) il Mac. È quindi possibile selezionare a quale sistema operativo avviare. Se interessati, fammelo sapere, e ti aiuterò a organizzare la RISE.

set output to do shell script "diskutil list /dev/disk0"
repeat with row in paragraphs in output
    if row contains "Microsoft Basic Data" then
        set slice to last word in row

        set adminpass to "MYPASSWORDWENTHERE"

        tell application "Finder"
            set iconPath to (get name of startup disk) & ":Applications:Utilities:Boot Camp Assistant.app:Contents:Resources:DA.icns" as alias
        end tell

        try
            set askRestart to display dialog "Restart in Windows?" buttons {"Cancel", "Once", "Always"} default button 1 with icon iconPath
        on error
            exit repeat
        end try
        set doRestart to button returned of askRestart

        if doRestart is in {"Restart", "Once", "Always"} then
            set command to "bless --device /dev/" & slice & " --legacy --setBoot"
            if doRestart is in {"Restart", "Once"} then
                set command to command & " --nextonly"
            end if
            set command to command & "; shutdown -r now"
            try
                do shell script command password adminpass with administrator privileges
            end try
        end if

        exit repeat
    end if
end repeat