Mac, automazione delle ricerche itunes di un elenco di parole?

Question

Mac, automazione delle ricerche itunes di un elenco di parole?

#1 da (2 voti)

-1

Mi piacerebbe eseguire diverse ricerche nell'app per Mac di iTunes, facendo una pausa fino a quando non riprendo a eseguire la ricerca successiva. Ho un elenco di ricerche che desidero eseguire.

Quindi devo produrre un qualche tipo di script di automazione, che mi darà una sorta di pulsante da toccare per riprendere.

O ho bisogno di qualcosa che mi permetta di incollare l'elemento successivo nella mia lista ecc.

In pratica sto cercando di risparmiare un po 'di fatica dal dover digitare le parole ogni volta.

Ho dato un'occhiata ad automator, alfred, hazel e all'editor di mele. Ma non credo che nessuno di questi funzionerà.

automation copy-paste applescript automator

posta Jules 07.06.2017 - 22:40

fonte

1 risposta

Leggi altre domande sui tag automation copy-paste applescript automator

Data di rilascio per iOS 11? [chiuso] iPhone non si accende, ha perso tutte le informazioni di recupero

score 2 · Answer 1

Puoi fare qualcosa del genere in Applescript. iTunes fornisce un comando search che fornisce un riferimento a una traccia.

Quindi puoi usare questo comando in un ciclo che:

Visualizza una finestra di dialogo che richiede i termini di ricerca.
Una finestra di dialogo a scelta multipla mostra le corrispondenze di iTunes per questo termine di ricerca.
Seleziona la traccia desiderata da questa finestra di dialogo. Quindi puoi riprodurre la coda personalizzata una alla volta.

Codice:

set lst_tracks to {}
try
    repeat
        display dialog "Please enter search terms" buttons {"Stop Searching", "Search More"} default button 2 cancel button 1 default answer ""
        set the_text to (text returned of result)
        tell application "iTunes"
            set end of lst_tracks to my GetiTunesTrack(the_text)
        end tell
    end repeat
end try
if lst_tracks ≠ {} then
    set the_result to (display dialog "Start Playing?" buttons {"No", "Yes"} default button 2 cancel button 1)
    set the_button to button returned of the_result
    if the_button = "Yes" then
        try
            repeat with i in lst_tracks
                tell application "iTunes"
                    set the_track to (contents of i)
                    set track_name to name of the_track
                    play the_track
                    set the_result to (display dialog "Playing: " & track_name buttons {"Stop", "Next Track"} default button 2 cancel button 1)
                end tell
            end repeat
        on error
            tell application "iTunes" to stop
        end try
    end if
end if
display dialog "Finish"

on GetiTunesTrack(search_str)
    local lst_names

    set lst_names to {}
    tell application "iTunes"
        set lst_results to (search library playlist 1 for search_str)

        repeat with item_ref in lst_results
            set end of lst_names to name of item_ref
        end repeat

        set the_selection to item 1 of (choose from list lst_names with prompt "Choose a Track" default items (item 1 of lst_names))
        set the_track to first track of library playlist 1 whose (name is the_selection)
        return the_track
    end tell
end GetiTunesTrack