AppleScripting QuickTime Pro 7 per esportare file .png

Ecco il mio script da esportare in PNG scritto per Snow Leopard. Puoi adattare facilmente le tue esigenze ...

EDIT: Ecco il tuo codice che incorpora il codice originale che ho postato. Funziona come hai descritto tu volevi che l'applet funzionasse.

property type_list : {"M4V ", "mpg4"} -- e.g.: {"PICT", "JPEG", "TIFF", "GIFf"} 
property extension_list : {"mp4", "m4v", "mpg"} -- e.g.: {"txt", "text", "jpg", "jpeg"}, NOT: {".txt", ".text", ".jpg", ".jpeg"}
property typeIDs_list : {"public.mpeg-4"} -- e.g.: {"public.jpeg", "public.tiff", "public.png"}

on open these_items
    repeat with i from 1 to the count of these_items
        set this_item to item i of these_items
        set the item_info to info for this_item
        if folder of the item_info is true then
            process_folder(this_item)
        else
            try
                set this_extension to the name extension of item_info
            on error
                set this_extension to ""
            end try
            try
                set this_filetype to the file type of item_info
            on error
                set this_filetype to ""
            end try
            try
                set this_typeID to the type identifier of item_info
            on error
                set this_typeID to ""
            end try

            if (folder of the item_info is false) and (package folder of the item_info is false) and (alias of the item_info is false) and ((this_filetype is in the type_list) or (this_extension is in the extension_list) or (this_typeID is in typeIDs_list)) then
                process_file(this_item)
            end if
        end if
    end repeat
end open

-- this sub-routine processes folders 
on process_folder(this_folder)

    # Debug
    tell application "Finder" to set f to name of this_folder
    log "Processing folder: " & f

    set these_items to list folder this_folder without invisibles
    repeat with i from 1 to the count of these_items
        set this_item to alias ((this_folder as Unicode text) & (item i of these_items))
        set the item_info to info for this_item
        if folder of the item_info is true then
            process_folder(this_item)
        else
            try
                set this_extension to the name extension of item_info
            on error
                set this_extension to ""
            end try
            try
                set this_filetype to the file type of item_info
            on error
                set this_filetype to ""
            end try
            try
                set this_typeID to the type identifier of item_info
            on error
                set this_typeID to ""
            end try

            if (folder of the item_info is false) and (package folder of the item_info is false) and (alias of the item_info is false) and ((this_filetype is in the type_list) or (this_extension is in the extension_list) or (this_typeID is in typeIDs_list)) then
                process_file(this_item)
            end if
        end if
    end repeat
end process_folder

-- this sub-routine processes files 
on process_file(this_item)
    tell application "QuickTime Player 7"
        set play movie from beginning when opened to false

        open this_item

        tell front document

            # Remove extension from filename
            set n to (this_item as string)
            set n to text 1 thru ((offset of "." in n) - 1) of n

            # Use .png since it will be overwritten later on...
            set xFileStart to n & "_start.png"
            set xFileEnd to n & "_end.png"

            # Positions (in seconds) in video to stop and take frames
            set sPos to 1
            set ePos to 1

            # Move for start frame
            set current time to (time scale * sPos)
            export to xFileStart as BMP using default settings with replacing

            # Move for end frame
            set current time to (duration - (time scale * ePos))
            export to xFileEnd as BMP using default settings with replacing

            close
        end tell

        # Do the actual conversion to PNG
        tell application "Image Events"
            set bmpFile to open file xFileStart
            save bmpFile as PNG
            set bmpFileEnd to open file xFileEnd
            save bmpFile as PNG
        end tell

    end tell
end process_file

L'Applescript che stai utilizzando per Quicktime non è corretto e stai chiedendo di eseguire comandi provenienti dalle aggiunte standard. I percorso per

QuickTime non lo capirà e fallirà. Allo stesso modo:

set frameOne of this_item to track (beginning)
set frameEnd of this_item to track (end)

QT non saprà che inizio e fine sono

Dovresti leggere il dizionario Quicktime 7 per comprenderne la sintassi.

In Script Editor vai al menu di Window- > Libreria

Questo farà apparire la finestra della libreria dei dizionari delle applicazioni.

Dubito che QT7 sia elencato, quindi vai al finder e trova QT7. Normalmente si trova nella cartella / Applicazioni / Utility .

Trascinalo nella finestra della libreria dei dizionari delle applicazioni.

Quindi fai doppio clic.

Si aprirà un dizionario. Leggilo per capire cosa può capire QT7.

Ora lo script.

Non ho toccato nessuno dei tuoi file di controllo.

Quello che ho cambiato è il contenuto del gestore process_file () . E aggiungi qualche Objective - C per semplificare il recupero del percorso del file e del nome del file.

Non preoccuparti troppo delle cose Objective -c. Puoi ancora usare l'applescript convenzionale che capisci se vuoi sostituirlo.

Le parti importanti sono:

Impostazione della posizione della testina di riproduzione e dell'esportazione del film. Poiché utilizziamo BMP, verrà esportato solo il frame corrente.

Avviso Imposto l'inizio a 0 e la fine dell'intera durata del film - 20.

Da quanto ho capito le misure sono in millisecondi. Quindi avere -20 della fine non dovrebbe fare molta differenza per ciò che catturi. Ma lo faccio perché uno dei miei video di prova ha avuto problemi a ottenere l'ultimo frame per l'intera durata. Ho ricevuto un errore dicendo frame non valido. Cambialo leggermente prima di risolvere il problema.

Uso anche un po 'di riga di comando per convertire il bmp in un png.

Ancora una volta per semplificare le cose (almeno per me) puoi usare il tuo metodo qui, se vuoi.

use scripting additions
use framework "Foundation"



(* TO FILTER FOR SPECIFIC FILES, ENTER THE APPROPRIATE DATA IN THE FOLLOWING LISTS: *)
property type_list : {"M4V ", "mpg4"} -- e.g.: {"PICT", "JPEG", "TIFF", "GIFf"} 
property extension_list : {"mp4", "m4v", "mpg"} -- e.g.: {"txt", "text", "jpg", "jpeg"}, NOT: {".txt", ".text", ".jpg", ".jpeg"}
property typeIDs_list : {"public.mpeg-4"} -- e.g.: {"public.jpeg", "public.tiff", "public.png"}


-- This droplet processes files dropped onto the applet 
on open these_items
    repeat with i from 1 to the count of these_items
        set this_item to item i of these_items
        set the item_info to info for this_item
        if folder of the item_info is true then
            process_folder(this_item)
        else
            try
                set this_extension to the name extension of item_info
            on error
                set this_extension to ""
            end try
            try
                set this_filetype to the file type of item_info
            on error
                set this_filetype to ""
            end try
            try
                set this_typeID to the type identifier of item_info
            on error
                set this_typeID to ""
            end try
            if (folder of the item_info is false) and (package folder of the item_info is false) and (alias of the item_info is false) and ((this_filetype is in the type_list) or (this_extension is in the extension_list) or (this_typeID is in typeIDs_list)) then
                process_file(this_item)
            end if
        end if
    end repeat
end open

-- this sub-routine processes folders 
on process_folder(this_folder)
    set these_items to list folder this_folder without invisibles
    repeat with i from 1 to the count of these_items
        set this_item to alias ((this_folder as Unicode text) & (item i of these_items))
        set the item_info to info for this_item
        if folder of the item_info is true then
            process_folder(this_item)
        else
            try
                set this_extension to the name extension of item_info
            on error
                set this_extension to ""
            end try
            try
                set this_filetype to the file type of item_info
            on error
                set this_filetype to ""
            end try
            try
                set this_typeID to the type identifier of item_info
            on error
                set this_typeID to ""
            end try
            if (folder of the item_info is false) and (package folder of the item_info is false) and (alias of the item_info is false) and ((this_filetype is in the type_list) or (this_extension is in the extension_list) or (this_typeID is in typeIDs_list)) then
                process_file(this_item)
            end if
        end if
    end repeat
end process_folder

-- this sub-routine processes files 
on process_file(this_item)
    tell application "QuickTime Player 7"
        set thisDoc to open this_item -- This will open the file in Quicktime
        tell thisDoc
            set xFolder to its path
            set duro to its duration

        end tell

    end tell

    -->> Objective - c to get the name and file path
    set xFolder to current application's NSString's stringWithString:(xFolder as string)

    set file_path to ((xFolder's stringByDeletingLastPathComponent) as string) & "/"


    set file_name to xFolder's lastPathComponent

    set file_name to (file_name's stringByDeletingPathExtension) as string
    --<<


    tell application "QuickTime Player 7"
        tell thisDoc
            set current time to 0
            set xFileStart to file_path & file_name & "_start.png"

            export track 1 to xFileStart as BMP using default settings with replacing
            delay 1
            do shell script ("sips -s format png " & (quoted form of xFileStart)) -- convert to png
            set current time to (duro - 20)
            set xFileEnd to file_path & file_name & "_end.png"
            export track 1 to xFileEnd as BMP using default settings with replacing
            delay 1
            do shell script ("sips -s format png " & (quoted form of xFileEnd)) -- convert to png
        end tell
        close thisDoc
    end tell
end process_file