Utilizzo di AppleScript per attivare la condivisione Internet non funzionante

Question

Utilizzo di AppleScript per attivare la condivisione Internet non funzionante

#1 da (1 voti)
#2 da (0 voti)

0

Sto usando un applescript per attivare l'opzione di condivisione Internet da 'System Pref > La condivisione'. Lavoro su MacOs 10.9.4. Ho trovato questo script su un forum e lo sto usando. Funziona bene, quando la finestra delle Preferenze di Sistema è aperta. Tuttavia, quando la finestra delle Preferenze di Sistema è chiusa, lo script apre la finestra Preferenze di Sistema e quindi visualizza questo messaggio di errore:

 System Events got an error: Can’t get menu item \"Sharing\" of menu \"View\" of menu bar 1 of process \"System Preferences\"." number -1728 from menu item "Sharing" of menu "View" of menu bar 1 of process "System Preferences"

Questo è il codice per lo script

tell application "System Preferences"
        activate
    end tell
    tell application "System Events"
        activate
        tell process "System Preferences"

            click menu item "Sharing" of menu "View" of menu bar 1
            delay 2
            tell window "Sharing"...
//code after this

Non sono esperto in AppleScript, ma devo solo usarlo per ottenere una scorciatoia da tastiera per attivare la condivisione su Internet. Inoltre, il forum che ho ricevuto dice che gli altri utenti sono in grado di usare lo script. Mi chiedo se abbia qualcosa a che fare con MAcOs 10.9

mavericks system-prefs applescript internet-sharing

posta code_enthu 04.08.2014 - 22:00

fonte

2 risposte

Leggi altre domande sui tag mavericks system-prefs applescript internet-sharing

Trova un file / cartella all'interno di un'altra cartella con l'interfaccia utente di OSX Scheda audio esterna, audio stereo per tutti gli altoparlanti

score 1 · Answer 1

Puoi utilizzare questo codice per attivare la condivisione con le impostazioni che erano già presenti:

tell application "System Preferences"
    activate
    set current pane to pane "com.apple.preferences.sharing"
end tell
tell application "System Events" to tell process "System Preferences"

    --find lock and click it if it is not unlocked
    repeat with x in buttons of window "Sharing"
        try
            if (value of attribute "AXTitle" of x) is equal to "Click the lock to make changes." then
                click x
            end if
        end try
    end repeat
    delay 5

    --find the checkbox for Internet Sharing and select the row so script can enable sharing through ethernet
    repeat with r in rows of table 1 of scroll area 1 of group 1 of window "Sharing"
        if (value of static text of r as text) starts with "Internet" then
            select r
        end if
    end repeat
    delay 2

    --enable Internet Sharing
    repeat with r in rows of table 1 of scroll area 1 of group 1 of window "Sharing"
        if (value of static text of r as text) starts with "Internet" then
            set sharingBool to value of checkbox of r as boolean
            select r
            if sharingBool is false then click checkbox of r
        end if
    end repeat
    delay 2

    if (exists sheet 1 of window "Sharing") then
        click button "Start" of sheet 1 of window "Sharing"
    end if
    delay 2

end tell
ignoring application responses
    tell application "System Preferences" to quit
end ignoring

Spero che questo aiuti!

score 0 · Answer 2

Un altro modo per aprire le Preferenze di sistema nel pannello Condivisione è ...

tell application "System Preferences"
    activate
    set current pane to pane id "com.apple.preferences.sharing"
end tell

Funzionerà se le Preferenze di Sistema sono aperte o meno.