Aggiunta di segnalibri per più schede in Safari con una scorciatoia da tastiera

Puoi usare questo Applescript; crea uno script di shell contenente i collegamenti per tutte le schede nella finestra corrente di Safari:

-- Set the default folder to Home -> bookmarks
set bookmarkFolder to "/bookmarks"
set username to do shell script "whoami"
set defaultFolder to POSIX file ("/Users/" & username & bookmarkFolder)

-- Initialize the text ot the script.
set cmd to "#!/bin/bash" & linefeed & linefeed

-- Add commands to open all the tabs.
tell application "Safari"
    set n to count of tabs in front window
    repeat with i from 1 to n
        set cmd to cmd & "open -g " & URL of tab i of front window & linefeed
    end repeat
end tell

-- Open/create a file and save the script.

tell me
    activate
    set scriptAlias to choose file name default name "tabset" default location (defaultFolder as alias)
end tell
set scriptPath to quoted form of POSIX path of scriptAlias
set scriptFile to open for access scriptAlias with write permission
set eof scriptFile to 0
write cmd to scriptFile starting at eof
close access scriptFile

-- Change the file attributes to make it double-clickable.
do shell script "chmod 777 " & scriptPath
do shell script "xattr -wx com.apple.FinderInfo '00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00' " & scriptPath

La versione originale è di Dr. Drang .

Ho cambiato due cose:

• lo script consente spazi bianchi nel nome del file
• la cartella predefinita è ~/bookmarks

Per eseguirlo, puoi utilizzare un launcher (ad esempio Quicksilver o Butler ) o includerlo in un System Service con Automator :

• crea il servizio
  • aggiungi un elemento Run Applescript
  • seleziona Service receives nessun input in Safari
  • incolla Applescript
• crea un collegamento in System Preferences > Keyboard > Shortcuts > Services
  • ⌘⌥D non funziona se lo usi per attivare la visibilità del Dock