Come creare una finestra di dialogo multi-campo in AppleScript (per richiedere tempo all'utente)?

Question

Come creare una finestra di dialogo multi-campo in AppleScript (per richiedere tempo all'utente)?

Naviga le tue risposte

#1 da (1 voti)

0

Ho un'applicazione di automazione che vorrei chiedere all'utente di inserire un'ora di scelta dell'utente.

Idealmente, vorrei che la finestra di dialogo avesse tre campi:

1) Campo orario

2) Minuti campo

3) Periodo (a pagamento)

I campi uno e due sono inseribili dall'utente e vi sono due punti tra i due campi. Il campo tre è un semplice elenco a discesa e l'utente deve selezionare una delle due opzioni.

Mi piacerebbe anche che l'AppleScript verificasse che qualsiasi testo venga digitato nei minuti e che i campi siano conformi agli standard di tempo e, in caso contrario, viene presentato un messaggio di errore e l'utente deve inserire nuovamente il testo. (Ad esempio, il testo inserito nel primo campo deve essere un numero a una cifra compreso tra 1 e 12 e il testo inserito nel secondo campo deve essere un numero a due cifre compreso tra 00 e 60.)

So che tutto ciò può essere realizzato in tre finestre di dialogo separate, ma preferirei che tutto fosse completato in una finestra di dialogo (per presentare all'utente una comoda interfaccia utente).

Non sono molto esperto in AppleScript, quindi questo progetto è estremamente ambizioso per me. Questo può essere realizzato in AppleScript?

Se questo comportamento non è possibile AppleScript, qualcuno può raccomandare una lingua alternativa simile in cui questo tipo di finestra di dialogo è possibile?

Grazie.

macos text-input applescript dialog

posta rubik's sphere 08.11.2016 - 05:17

fonte

1 risposta

Leggi altre domande sui tag macos text-input applescript dialog

MacbookPro non si avvierà senza USB-Key live. Bootloader avvitato? Come rimuovere adware su macOS Sierra 10.12.1?

score 1 · Answer 1

Non può essere fatto in AppleScript.

Tuttavia, ho trovato questo workaround , in cui il testo è stato inserito in ogni la linea di un campo è interpretata come una risposta separata:

-- multiple input dialog

on run -- example
    set {firstName, lastName} to (inputItems for {"• First Name", "• Last Name"} with title given prompt:"Enter the following items separated by a carriage return:")
    display dialog "First Name:  \"" & firstName & "\"" & return & "Last Name:  \"" & lastName & "\""
end run

to inputItems for someItems given title:theTitle, prompt:thePrompt
    (*
    displays a dialog for multiple item entry - a carriage return is used between each input item
    for each item in someItems, a line of text is displayed in the dialog and a line is reserved for the input
        the number of items returned are padded or truncated to match the number of items in someItems
    to fit the size of the dialog, items should be limited in length (~30) and number (~15)  
        parameters -        someItems [list/integer]: a list or count of items to get from the dialog
                        theTitle [boolean/text]: use a default or the given dialog title
                        thePrompt [boolean/text]: use a default or the given prompt text
        returns [list]:     a list of the input items
    *)
    if thePrompt is in {true, false} then -- "with" or "without" prompt
        if thePrompt then
            set thePrompt to "Input the following items:" & return & return -- default
        else
            set thePrompt to ""
        end if
    else -- fix up the prompt a bit
        set thePrompt to thePrompt & return & return
    end if

    if theTitle is in {true, false} then if theTitle then -- "with" or "without" title
        set theTitle to "Multiple Input Dialog" -- default
    else
        set theTitle to ""
    end if

    if class of someItems is integer then -- no item list
        set {theCount, someItems} to {someItems, ""}
        if thePrompt is not "" then set thePrompt to text 1 thru -2 of thePrompt
    else
        set theCount to (count someItems)
    end if
    if theCount is less than 1 then error "inputItems handler:  empty input list"
    set {theItems, theInput} to {{}, {}}

    repeat theCount times -- set the number of lines in the input
        set the end of theInput to ""
    end repeat
    set {tempTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, return}
    set {someItems, theInput} to {someItems as text, theInput as text}
    set AppleScript's text item delimiters to tempTID

    set theInput to paragraphs of text returned of (display dialog thePrompt & someItems with title theTitle default answer theInput)

    repeat with anItem from 1 to theCount -- pad/truncate entered items
        try
            set the end of theItems to (item anItem of theInput)
        on error
            set the end of theItems to ""
        end try
    end repeat
    return theItems
end inputItems