Aggiungi nomi di file allegati all'oggetto nel mio applecript?

Question

Aggiungi nomi di file allegati all'oggetto nel mio applecript?

#1 da (2 voti)

0

Sono un principiante con applescript. Sono riuscito a mettere insieme un piccolo script che aggiunge file selezionati dal finder a un allegato di posta elettronica come un flusso di lavoro di servizio. Ora ho bloccato l'ultimo numero. Mi piacerebbe aggiungere il nome del file all'oggetto. Ecco il applescript. Qualcuno potrebbe aiutare?

property mailSubjectPrefix : "Datei(en) für dich: "
property subjAttNameSeparator : ", "
property attachSeparator : "*******"
property attachPrefix : "Anhänge:"

set theSubject to "Datei(en): "
set theContent to "Datei(en) für dich:"
set recipientAddress to {}


tell application "Contacts"

    set recipientAddress to "[email protected]"

end tell




tell application "Finder"
-- Make a list to gather the names of the selected files
set fileAliases to {}
-- Get the selection of the frontmost Finder window
set fileSelection to the selection
-- Iterate of the selection
repeat with fileItem in fileSelection
    copy the fileItem as alias to the end of fileAliases
end repeat
-- Check if the selection is not empty
if the number of items of fileAliases is 0 then
    -- Audible feedback, so the script always does something.
    beep
else
    -- Now talk to mail to create the message
    tell application "Mail"
        set newMessage to make new outgoing message at beginning with properties { content:theContent, visible:true}
        set mailSubject to {}
        -- Set a recipient



        tell newMessage
            make new to recipient at end with properties {address:recipientAddress}



        set MailSubject to fileAliases

        set oTID to AppleScript's text item delimiters
        set AppleScript's text item delimiters to subjAttNameSeparator
        set subject to mailSubjectPrefix & (mailSubject as string)
        set AppleScript's text item delimiters to oTID




        end tell
        -- Attach all the selected files
        repeat with fileAlias in fileAliases
            make new attachment with properties {file name:fileAlias} at after the last paragraph of newMessage

        end repeat




        -- Put Mail in the foreground
        activate


    end tell
end if
end tell

finder applescript

posta Markus 20.01.2018 - 23:30

fonte

1 risposta

Leggi altre domande sui tag finder applescript

La pressione del touchpad Force lo danneggia gravemente? MacBook Pro Late 2011 vale la pena di aggiornare? [chiuso]

score 2 · Accepted Answer

Cambia semplicemente questa linea:

    set MailSubject to fileAliases

a questo:

    set mailSubject to fileAliases as string

    tell application "Finder" to get insertion location
    set text item delimiters of AppleScript to result

    set mailSubject to rest of text items of mailSubject

APPENDICE:

Spero che tu non osservi che lo script che presenti nella tua domanda contiene molto codice ridondante e / o mal formattato. Funziona bene, quindi non è di grande importanza al di là di un aspetto estetico. Tuttavia, uno script più ordinato e ben fatto semplifica l'identificazione degli errori e, nel caso di script più lunghi che eseguono più attività, verrà eseguito in modo più efficiente / veloce.

Quindi, con questo in mente, mi sono preso la libertà di riscrivere il tuo script, che spero possa essere utile come strumento di apprendimento, o semplicemente essere più facile andare d'accordo se vuoi apportare ulteriori modifiche ad esso te stesso.

    property mailSubjectPrefix : "Datei(en) für dich: "
    property subjAttNameSeparator : ", "
    property attachSeparator : "*******"
    property attachPrefix : "Anhänge:"

    set theSubject to "Datei(en): "
    set theContent to "Datei(en) für dich:\n\n"
    set recipientAddress to "[email protected]"


    -- Get the selection of the frontmost Finder window
    -- as a list of aliases
    tell application "Finder"
        set fileAliases to the selection as alias list
        set text item delimiters of AppleScript to insertion location
        set fileNames to rest of text items of (fileAliases as text)
    end tell


    -- Check if the selection is not empty
    if the number of fileAliases is 0 then return beep

    -- Now talk to mail to create the message
    tell application "Mail"
        set text item delimiters of AppleScript to subjAttNameSeparator
        tell (make new outgoing message at beginning ¬
            with properties {content:theContent, visible:true, subject:mailSubjectPrefix & (fileNames as string)})

            -- Add the recipient
            make new to recipient at end with properties {address:recipientAddress}

            -- Attach all the selected files
            repeat with fileAlias in fileAliases
                make new attachment with properties {file name:fileAlias} at after the last paragraph
            end repeat

        end tell

        -- Put Mail in the foreground
        activate
    end tell

Se hai bisogno di chiarimenti su qualsiasi punto, sentiti libero di lasciare un commento e ti risponderò.