Un Apple Applescript che si aggiunge ai tag solo quando non corrisponde a una parte della stringa del tag?

Question

Un Apple Applescript che si aggiunge ai tag solo quando non corrisponde a una parte della stringa del tag?

#1 da (0 voti)

1

Sto cercando di trovare un modo per aggiungere una parola chiave o un gruppo di parole / tag / stringhe a un set di tracce iTunes selezionate se non sono state aggiunte. Un caso d'uso sarebbe aggiungere metadati extra in un commento come (live) o (remix).

Se alcune tracce precedentemente contenute (in diretta) durante l'aggiunta, non le aggiungerebbero, solo i file non corrispondenti. Quindi un tag di commento contenente (remix) (veloce) (fisarmonica) (casuale) diventerebbe in seguito (remix) (veloce) (fisarmonica) (casuale) (live) . Tuttavia, se riapplicato, salta questa traccia.

La cosa più vicina che riesco a trovare è Smart Append , ma è per Windows solo (essendo JavaScript).

Il famoso Doug ha un append allo script di tag , ma non ha qualsiasi capacità di rilevamento. Ho sbirciato nel codice (facendo clic con il tasto destro del mouse > Mostra contenuto della confezione) e non riesco a capire come modificare lo script.

Qualcuno sa di uno script esistente o un modo per modificare lo script esistente?

itunes applescript music id3-tag

posta ffolke 03.06.2012 - 02:28

fonte

1 risposta

Leggi altre domande sui tag itunes applescript music id3-tag

Mostra le date delle foto durante la revisione delle facce Apre una cartella nel browser predefinito

score 0 · Accepted Answer

Questo script funziona se la parola chiave è tra parentesi come nell'esempio, altrimenti la corrispondenza parziale sarà un problema. Esempio: " veloce " corrispondenza " più veloce "

property matchCase : true -- or false -- change according to your needs 

set myTitle to "Append to Comments Tag, if the keyword not exists"
set keywordSeparator to ";" -- keyword separator

tell application "iTunes"
    set sel to selection
    if sel is not {} then -- if tracks are selected...
        set s to "s"
        set x to (length of sel)
        if x is 1 then set s to ""
        set be to (display dialog "Enter keyword to append to the beginning or ending of each selected track's Comments tag:" & return & return & " If more than one keyword, use this character " & keywordSeparator & " as separator." default answer "" buttons {"Cancel", "Beginning", "Ending"} cancel button 1 with title myTitle)
        set appendage to text returned of be
        set buttonOpt to button returned of be is equal to "Ending"
        if appendage is "" then return
        set listOfAppendage to my makeListOfKeywords(keywordSeparator, appendage)
        set oldfi to fixed indexing
        set fixed indexing to true
        repeat with t from 1 to x
            tell contents of item t of sel
                try
                    set tresult to my checkExistKeywords(comment, listOfAppendage, buttonOpt)
                    if tresult is not false then set comment to tresult
                end try
            end tell
        end repeat
        set fixed indexing to oldfi
        activate
        display dialog "Done!" buttons {"OK"} default button 1 with icon 1 with title myTitle giving up after 4
    else
        activate
        display dialog "You must select some tracks first." buttons {"Cancel"} default button 1 with title myTitle
    end if
end tell

on checkExistKeywords(tagValue, tKeywords, tOpt)
    set isAdding to false
    repeat with tKey in tKeywords
        if matchCase then
            considering case
                contents of tKey is not in tagValue
            end considering
        else --Ignore Case
            contents of tKey is not in tagValue
        end if
        if the result then -- no match
            set isAdding to true
            if tOpt then
                set tagValue to tagValue & tKey
            else
                set tagValue to tKey & tagValue
            end if
        end if
    end repeat
    if isAdding then return tagValue
    return false -- nothing to add
end checkExistKeywords

on makeListOfKeywords(tofind, t)
    set ditd to text item delimiters
    set text item delimiters to tofind
    set t to text items of t
    set text item delimiters to ditd
    return t
end makeListOfKeywords