Come simulare più clic del mouse tenendo premuto il pulsante del mouse?

Ho fatto una soluzione per te. Ha alcuni pezzi, potrebbe aver avuto bisogno di me per sempre, e potrebbe probabilmente usare un po 'di lucidatura, ma è abbastanza vicino a quello che volevi. L'unica cosa che non riesco a vedere siamo in grado di realizzare è tenere premuto il mouse per farlo. Non sono riuscito a trovare nulla che ci permettesse di usare il mouseup per disattivare il nostro ciclo click, quindi ho usato un interruttore: fai clic una volta per iniziare i nostri pazzi clic e fai di nuovo clic per interromperlo. start e stop)

Stiamo usando applescript, uno strumento da riga di comando per OSX chiamato MouseTools e un'applicazione chiamata MagicPref per assegnare lo script a uno dei nostri pulsanti del mouse.

una volta scaricato ed estratto MouseTools, è solo uno script batch. Ho messo il mio e i miei applescripts all'interno della stessa cartella (ho chiamato la cartella superclicks ). Ora abbiamo solo bisogno di creare un ciclo che clic nella posizione corrente del mouse e un modo per uscire da quel ciclo.

Ecco le due app per apple che creiamo:

launch.app

global thisFile
set thisFile to (path to me)

global thisFolder
tell application "Finder" to set thisFolder to container of thisFile as text


# Function to check current state / should we should stop clicking
on checkstate()
local clickState
tell application "Finder"
    if exists file (thisFolder & "STOP_CLICKING.txt") then
        set clickState to false
    else if exists file (thisFolder & "CLICKING.txt") then
        set clickState to true
    else
        set clickState to null
    end if
end tell
return clickState
end checkstate

#function to update state of clicking via text files
#im sure there is a better way, but this certainly works
on togglestate()
if checkstate() is null then
    tell application "Finder" to make new file at thisFolder with properties     {name:"CLICKING.txt"}
else if checkstate() is true then
    tell application "Finder" to make new file at thisFolder with properties {name:"STOP_CLICKING.txt"}
else if checkstate() is false then
    tell application "Finder"
        delete file (thisFolder & "CLICKING.txt")
        delete file (thisFolder & "STOP_CLICKING.txt")
    end tell
end if
end togglestate


togglestate()
#we dont really want 3 states so we'll toggle again after a reset
if checkstate() is null then togglestate()

if checkstate() is true then
tell application "Finder"
    open (thisFolder & "clicking_script")
end tell
end if

clicking_script.app

global thisFile
set thisFile to (path to me)

global thisFolder
tell application "Finder" to set thisFolder to container of thisFile as text


## Function to check current state / should we should stop clicking
on checkstate()
local clickState
tell application "Finder"
    if exists file (thisFolder & "STOP_CLICKING.txt") then
        set clickState to false
    else if exists file (thisFolder & "CLICKING.txt") then
        set clickState to true
    else
        set clickState to null
    end if
end tell
return clickState
end checkstate


# let the clicking begin
on crazyClick()
set x to 0
repeat until checkstate() = false or x = 1000
    do shell script ((POSIX path of thisFolder as text) & "mousetools -leftClick")
    do shell script ((POSIX path of thisFolder as text) & "mousetools -releaseMouse")
    set x to (x + 1)
    delay 0
end repeat
end crazyClick

crazyClick()

Questi due script devono essere salvati come applicazioni. Una volta ottenuti questi tre elementi nella cartella, tutto ciò che devi fare è assegnare launch.app come applicazione personalizzata da avviare per un particolare clic utilizzando MagicPrefs.

Quando attivi lo script fa clic come un matto finché non lo attivi di nuovo, interrompendo il ciclo aggiungendo alcuni file di testo vuoti alla cartella. Abbiamo usato i file di testo come un modo semplice per avere variabili esterne.

Ho zippato tutti i file per un facile download.

Potrebbe non essere perfetto ma è sicuramente un buon inizio per vedere quale creatività può essere realizzata con l'automazione.