È possibile mantenere la scorciatoia Chrome di Chrome per la scheda di sfondo, mentre si utilizza AppleScript per automatizzare la creazione di una nuova scheda?

Penso che questo farà ciò che stai chiedendo. Ho modificato il codice originale per vedere quale processo è in primo piano al momento in cui esegue , al fine di branch e test in base alle condizioni espresse nella domanda utilizzando checkModifierKeys *. per vedere se il tasto ⌘ comando è stato premuto quando Google Chrome è il processo in primo piano nel momento in cui il servizio è eseguito . * (Non ho alcuna affiliazione con il blog di Charles Poynton o con CheckModifierKeys di Stefan Klieme se non per aver usato questo programma per alcuni anni senza problemi.)

Come codificato, si presuppone che checkModifierKeys si trovi in /usr/local/bin/ . Modifica secondo necessità.

Vedi i commenti nel if theFrontmostProcessWhenRun is "Google Chrome" then blocco per il suo flusso logico .

    on run {input, parameters}

        --  # Get the name of frontmost process at the time the services was run.
        --  #
        --  # This is used later in an if statement block for when if Google Chrome was frontmost process when run
        --  # to check that the value returned from checkModifierKeys was for the command key being pressed.

        tell application "System Events"
            set theFrontmostProcessWhenRun to get name of process 1 where frontmost is true
        end tell

        (*
    When triggering this Service in applications other than Google Chrome, such as TextEdit, the Chrome window opens in the background. This command brings the Chrome window to the foreground:
*)
        activate application "Google Chrome"

        (*
    Converting the selected text to plain text to remove any formatting:
        From: http://lifehacker.com/127683/clear-text-formatting-on-os-x
*)
        set selectedText to input
        set selectedText to (selectedText as text)

        (*
    Removing any line breaks and indentations in the selected text:
        From: http://stackoverflow.com/a/12546965 
*)

        set AppleScript's text item delimiters to {return & linefeed, return, linefeed, character id 8233, character id 8232}
        set plainTextSelectedText to text items of (selectedText as text)
        set AppleScript's text item delimiters to {" "}
        set plainTextSelectedText to plainTextSelectedText as text

        (* Assigning variables: *)
        set baseURL to "https://www.google.com/search?q="
        set finalLink to baseURL & plainTextSelectedText

        (* Opening webpage in Chrome: *)
        (*
    The following tell block creates a new tab, located immediately after the currently open tab, which is what I want to occur.
        From: http://apple.stackexchange.com/questions/271702/applescript-how-to-open-a-link-in-google-chrome-in-a-new-adjacent-tab/271709#271709
*)


        if theFrontmostProcessWhenRun is "Google Chrome" then
            --  # Google Chrome was the frontmost process when the service was run.
            if ((do shell script "/usr/local/bin/checkModifierKeys") as integer) is equal to 256 then
                --  # The command key was pressed when the service was run.
                tell application "Google Chrome"
                    --  # See Note: below.
                    set activeTab to active tab index of front window
                    tell front window to make new tab at after (get active tab) with properties {URL:finalLink} -- open a new tab after the current tab
                    set active tab index of front window to activeTab
                end tell
            else
                tell application "Google Chrome"
                    tell front window to make new tab at after (get active tab) with properties {URL:finalLink} -- open a new tab after the current tab
                end tell
            end if
        else
            --  # Google Chrome was not the frontmost process when the service was run.
            tell application "Google Chrome"
                tell front window to make new tab at after (get active tab) with properties {URL:finalLink} -- open a new tab after the current tab
            end tell
        end if

    end run

Nota: quando Google Chrome è in primo piano al momento il servizio è eseguito e il tasto ⌘ comando viene premuto, questo ottiene l'attuale active tab index e lo imposta di nuovo dopo aver creato la nuova scheda . Questo è inteso come soluzione temporanea in quanto è un po 'cauto, ma meglio di niente finché non si trova una soluzione più elegante di un problema.